[gentoo-commits] repo/gentoo:master commit in: dev-python/ini2toml/

["Michał Górny" <mgorny@gentoo.org>]

commit:     481b0b697edc7269a11088830f7a837ef4ace02a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 14 06:18:04 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 14 06:18:04 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=481b0b69

dev-python/ini2toml: Bump to 0.15

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ini2toml/Manifest             |  1 +
 dev-python/ini2toml/ini2toml-0.15.ebuild | 59 ++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/ini2toml/Manifest b/dev-python/ini2toml/Manifest
index 0c7dd6d3c7e8..865139b10a3a 100644
--- a/dev-python/ini2toml/Manifest
+++ b/dev-python/ini2toml/Manifest
@@ -1 +1,2 @@
 DIST ini2toml-0.14.tar.gz 108296 BLAKE2B f09ac924eea976b82d68b12132cc671cb5b0f57734fc2a4f4b0dc68e0a9e20d4f906ab757e662c152a5d7db9f0bad17bd28644524bd18a16895ad489eac1d29d SHA512 d29155ae1069084381aef852145a6c734ea4e1e8c6847174fff98bca497cbb4289ee791b26541c6027b716845dd23fc251dde531c6cb9c62d490e4bfed5f862e
+DIST ini2toml-0.15.tar.gz 109236 BLAKE2B d844f45e14379af974c86283daa1aa6fa5d9934b219fdf02be9abbeb873487b36eecede39dafc261f5ab2a6bfadceaea3b16611f5d6c1f3bc88a28574a11dc14 SHA512 5726c745972fbdf6a254ccd44133c5c65368f531c17efda3b83323c2c9e450d508fe57f1aa0919c0de6cc6e18d6a974b75dc50ecf29c852d367bc03891f0486c

diff --git a/dev-python/ini2toml/ini2toml-0.15.ebuild b/dev-python/ini2toml/ini2toml-0.15.ebuild
new file mode 100644
index 000000000000..86e379f5596f
--- /dev/null
+++ b/dev-python/ini2toml/ini2toml-0.15.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Automatically conversion of .ini/.cfg files to TOML equivalents"
+HOMEPAGE="
+	https://pypi.org/project/ini2toml/
+	https://github.com/abravalheri/ini2toml/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-20.7[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-59.6[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-0.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/configupdater[${PYTHON_USEDEP}]
+		dev-python/tomli[${PYTHON_USEDEP}]
+		dev-python/tomlkit[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov ini2toml --cov-report term-missing::' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# validate_pyproject is not packaged
+		tests/test_examples.py
+	)
+	local EPYTEST_DESELECT=()
+
+	# Incompatible with pyproject-fmt-2 API:
+	# https://github.com/abravalheri/ini2toml/issues/103
+	if ! has_version "<dev-python/pyproject-fmt-2[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_cli.py::test_auto_formatting
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}