[gentoo-commits] repo/gentoo:master commit in: x11-plugins/wmbiff/

["Sam James" <sam@gentoo.org>]

commit:     67c1593710b2cae3373d73c069163551d473126e
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Mon May 13 01:04:11 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon May 13 01:05:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67c15937

x11-plugins/wmbiff: update EAPI 7 -> 8

Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 x11-plugins/wmbiff/wmbiff-0.4.36-r1.ebuild | 45 ++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/x11-plugins/wmbiff/wmbiff-0.4.36-r1.ebuild b/x11-plugins/wmbiff/wmbiff-0.4.36-r1.ebuild
new file mode 100644
index 000000000000..b877701251c6
--- /dev/null
+++ b/x11-plugins/wmbiff/wmbiff-0.4.36-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="WMBiff is a dock applet for WindowMaker which can monitor up to 5 mailboxes"
+HOMEPAGE="https://www.dockapps.net/wmbiff"
+SRC_URI="https://www.dockapps.net/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="crypt"
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXpm
+	crypt? (
+		>=dev-libs/libgcrypt-1.2.1:0
+		>=net-libs/gnutls-2.2.0
+		)"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig"
+
+DOCS="ChangeLog FAQ NEWS README TODO wmbiff/sample.wmbiffrc"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.4.27-invalid-strncpy.patch
+	"${FILESDIR}"/${P}-ar.patch
+	)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# -Werror=lto-type-mismatch
+	# https://bugs.gentoo.org/864855
+	# https://groups.google.com/g/wmaker-dev/c/Z9mU9x4qxs0
+	filter-lto
+
+	econf $(use_enable crypt crypto)
+}