[gentoo-commits] repo/proj/guru:dev commit in: media-libs/imgui/

["Gonçalo Negrier Duarte" <gonegrier.duarte@gmail.com>]

commit:     0a4e50def5503aed24844901bafdd7189def94eb
Author:     Gonçalo Negrier Duarte <gonegrier.duarte <AT> gmail <DOT> com>
AuthorDate: Fri May 10 13:54:50 2024 +0000
Commit:     Gonçalo Negrier Duarte <gonegrier.duarte <AT> gmail <DOT> com>
CommitDate: Fri May 10 14:00:47 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=0a4e50de

media-libs/imgui: add 1.90.6

Signed-off-by: Gonçalo Negrier Duarte <gonegrier.duarte <AT> gmail.com>

 media-libs/imgui/Manifest            |  1 +
 media-libs/imgui/imgui-1.90.6.ebuild | 67 ++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-libs/imgui/Manifest b/media-libs/imgui/Manifest
index 5e96536e09..26ede19381 100644
--- a/media-libs/imgui/Manifest
+++ b/media-libs/imgui/Manifest
@@ -1 +1,2 @@
 DIST imgui-1.89.9.tar.gz 1609452 BLAKE2B d5f361acf4318b05066720e9da2ed06db760c482440fc7fb2ca95ce5dd88d9a9a010697c831d3e188baec69819c0a0925e98134c191d5e1856ab43e4dbf9b64f SHA512 42021b06b611b58222b09fab8db2c34e992c3dc4fbaa175e09833c66c90d04b4a4e7def16a732535335c0ac5ff014d235835511a5d9a76d32b4395b302146919
+DIST imgui-1.90.6.tar.gz 1677600 BLAKE2B 2dba4e461e5d771f6764a9a4ff281c0e5ceb1b9467c0640171a4c86dc5a53a172815f2dd10241cb5148549035e6db44f6a20f219c7ce95bac6e1afd9b72402a4 SHA512 c9ff56ec6f8eb05b5034bb0b886568e843743a4313e36613db214f6080506703d5ed2ee606c88cd8957e73575e2b0e39deb52e1ac0c1a6e0a9fe38bca5e6dc0e

diff --git a/media-libs/imgui/imgui-1.90.6.ebuild b/media-libs/imgui/imgui-1.90.6.ebuild
new file mode 100644
index 0000000000..bed80af29a
--- /dev/null
+++ b/media-libs/imgui/imgui-1.90.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+MESON_WRAP_VER="1"
+
+DESCRIPTION="Bloat-free graphical user interface library for C++"
+HOMEPAGE="
+	https://github.com/ocornut/imgui
+"
+
+SRC_URI="https://github.com/ocornut/imgui/archive/v${PV}.tar.gz -> imgui-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="opengl vulkan glfw sdl2 sdl_renderer webgpu allegro5"
+
+RDEPEND="
+	dev-libs/stb:=
+	media-libs/glew[${MULTILIB_USEDEP}]
+	allegro5? ( media-libs/allegro:5[${MULTILIB_USEDEP}] )
+	glfw? ( media-libs/glfw:0[${MULTILIB_USEDEP}] )
+	opengl? ( virtual/opengl[${MULTILIB_USEDEP}] )
+	sdl2? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
+	sdl_renderer? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
+	vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Use custom meson.build and meson_options.txt to install instead of relay on packages
+	cp "${FILESDIR}/${PN}-meson.build" "${S}/meson.build" || die
+	cp "${FILESDIR}/${PN}-meson_options.txt" "${S}/meson_options.txt" || die
+	sed -i "s/  version: 'PV',/  version: '${PV}',/g" "${S}/meson.build" || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddx9=disabled
+		-Ddx10=disabled
+		-Ddx11=disabled
+		-Ddx12=disabled
+		-Dmetal=disabled
+		$(meson_feature opengl)
+		$(meson_feature vulkan)
+		$(meson_feature glfw)
+		$(meson_feature sdl2)
+		$(meson_feature sdl_renderer)
+		$(meson_feature webgpu)
+		-Dosx=disabled
+		-Dwin=disabled
+		$(meson_feature allegro5)
+	)
+	meson_src_configure
+}