[gentoo-commits] repo/gentoo:master commit in: dev-python/html5lib/

["Michał Górny" <mgorny@gentoo.org>]

commit:     096bfe3268a87a5fcdacaa0d16dde921422bf1f9
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May  9 19:04:35 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May  9 19:05:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=096bfe32

dev-python/html5lib: Eliminate dev-python/mock dep

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/html5lib/html5lib-1.1-r2.ebuild | 49 ++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-python/html5lib/html5lib-1.1-r2.ebuild b/dev-python/html5lib/html5lib-1.1-r2.ebuild
new file mode 100644
index 000000000000..02e9043828bf
--- /dev/null
+++ b/dev-python/html5lib/html5lib-1.1-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HTML parser based on the HTML5 specification"
+HOMEPAGE="
+	https://github.com/html5lib/html5lib-python/
+	https://html5lib.readthedocs.io/
+	https://pypi.org/project/html5lib/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-pytest6.patch
+)
+
+RDEPEND="
+	>=dev-python/six-1.9[${PYTHON_USEDEP}]
+	dev-python/webencodings[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-expect[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -e 's:from mock:from unittest.mock:' \
+		-i html5lib/tests/test_meta.py || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_expect
+}