[gentoo-commits] repo/gentoo:master commit in: dev-util/umockdev/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     13484650d4ddeba6a24231f743ab1ec715b16775
Author:     Brahmajit Das <brahmajit.xyz <AT> gmail <DOT> com>
AuthorDate: Mon Apr 22 13:25:33 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat May  4 18:11:43 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=13484650

dev-util/umockdev: add 0.18.1

Closes: https://bugs.gentoo.org/929077
Signed-off-by: Brahmajit Das <brahmajit.xyz <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/36355
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-util/umockdev/Manifest               |  1 +
 dev-util/umockdev/umockdev-0.18.1.ebuild | 59 ++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index e5c49995815b..11fc9b425c3d 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1 +1,2 @@
 DIST umockdev-0.17.18.tar.xz 491668 BLAKE2B 106efc5674475383abb7618f087b3536441ae1fa30d6a92b689c1119ff62e06a20a6a529968f2b978f8ed410fc2033c95b86e214d4d4a576cdb9e68ee09a1853 SHA512 3d8d2487b4350e4ce28a5c163cbb1b92da9f5a5317e74da46ccaa62a6b8e938a6758e241d0dd2e9f50fdee4aef24d36585a24cfec1ad99fb4799a01008d9987b
+DIST umockdev-0.18.1.tar.xz 493816 BLAKE2B 314969269e8e5b70b65c89345b659cf2784eb71cfd2c010e8043cc38b6965dce0dcadac6ffab266f4b926e46bb0939d6c159ee17fbf341eed7a11f932a80a2ad SHA512 4897c12fca8d1927a2840efbbd8281a95102b328cc682ffed10cd4e29b80f26b80df55fbd3736297ee4633561b007beda369bd3ddf07eb71bdd1d7c0222243c8

diff --git a/dev-util/umockdev/umockdev-0.18.1.ebuild b/dev-util/umockdev/umockdev-0.18.1.ebuild
new file mode 100644
index 000000000000..d6f2d4357dec
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.18.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson-multilib python-any-r1 vala
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/martinpitt/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}