[gentoo-commits] repo/gentoo:master commit in: dev-scheme/guile-git/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     ff6dc92558fb9d04bb2bb4cd00d32c88c75c5ccd
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Thu May  2 14:19:06 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu May  2 15:01:01 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff6dc925

dev-scheme/guile-git: bump to 0.7.0

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/guile-git/Manifest               |  1 +
 dev-scheme/guile-git/guile-git-0.7.0.ebuild | 72 +++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-scheme/guile-git/Manifest b/dev-scheme/guile-git/Manifest
index fe2f5ce6a405..e337443951ec 100644
--- a/dev-scheme/guile-git/Manifest
+++ b/dev-scheme/guile-git/Manifest
@@ -1 +1,2 @@
 DIST guile-git-v0.6.0.tar.bz2 99833 BLAKE2B 51109cc5f037cffd5e8a6dd1b0ce99631ffb524e209a8b081c33a188ead78d26c76dbb9590e3891c056eb7853da57b7e3f3f08ef3723465bd7ab43671c3d018b SHA512 519b5dafd83b5967403929e347fa2b81fcec97136459722fdc95357cbeba9d519807b8863b17a85fc426e53e8f78f5d3979f96bbb32548bcf598827f3f228219
+DIST guile-git-v0.7.0.tar.bz2 100454 BLAKE2B a94a8f81949f1caf4bb31ed498856561fd88d541c3f8ccced1a5f6633f189a09d8961b5fdf7810393e110665e77db48bf4aeb3c756437e2b75f614710eaac521 SHA512 6207464bc48de8e33fde0365c198e42c21719e5ffb27e30ab3277f88d04ccc4a2fe4964c0019333be8f047d3ddc76f1c98e6e060311ce6b2a13ac670c0663226

diff --git a/dev-scheme/guile-git/guile-git-0.7.0.ebuild b/dev-scheme/guile-git/guile-git-0.7.0.ebuild
new file mode 100644
index 000000000000..8984ab9f3bf9
--- /dev/null
+++ b/dev-scheme/guile-git/guile-git-0.7.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Guile bindings of git"
+HOMEPAGE="https://gitlab.com/guile-git/guile-git/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://gitlab.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/${PN}/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	S="${WORKDIR}/${PN}-v${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+
+# Works without sandbox. But under sandbox sshd claims to break the protocol.
+RESTRICT="test"
+
+# older libgit seems to be incompatible with guile-git bindings
+# https://github.com/trofi/nix-guix-gentoo/issues/7
+RDEPEND="
+	>=dev-libs/libgit2-1:=
+	>=dev-scheme/guile-2.0.11:=
+	dev-scheme/bytestructures
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# guile is trying to avoid recompilation by checking if file
+	#     /usr/lib64/guile/2.2/site-ccache/<foo>
+	# is newer than
+	#     <foo>
+	# In case it is instead of using <foo> guile
+	# loads system one (from potentially older version of package).
+	# To work it around we bump last modification timestamp of
+	# '*.scm' files.
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_test() {
+	emake VERBOSE="1" check-TESTS
+}
+
+src_install() {
+	default
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}