[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-contacts/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     962ca7353a0fd32de730c1819db4d20cf074225a
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Thu Jan 11 14:33:46 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Apr 28 20:43:26 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=962ca735

gnome-extra/gnome-contacts: Bump to 46.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-contacts/Manifest                |  1 +
 .../gnome-contacts/gnome-contacts-46.0.ebuild      | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index 6de76fb43191..98b40f2b486a 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1 +1,2 @@
 DIST gnome-contacts-45.1.tar.xz 402748 BLAKE2B 02cb3fd3ebcfd4e33add4706b1746940a14d680697ddaf54f9e006a14c15e7a11f791af2704b40573b59c6348ba3f1e1e216b514b1bc5fed990f0e8eaf1dc45b SHA512 87fc5b235e955ca347950306d37d0d8aea71dbcdb0f8d5c45d96da3a316f5e40da6004d6c5ab3674acdf7237f81bd508486c90130d01b045ee0c0582b04ba8aa
+DIST gnome-contacts-46.0.tar.xz 410040 BLAKE2B bff36046bf6a37d5550458d55078ec2dfc0704c31365e925788ed64cf03af88ae73be45e256c770fdbc43e65dba5487812fafe169168c2ef625853eaeff17e90 SHA512 adadbb4038053e402f131f530b61fa1c33008eac819d2c03e0a024080bc7e5e24b022a0e9d773ffa03e20324296338d1c3115d25a39f6a3fddd4480de3c8980e

diff --git a/gnome-extra/gnome-contacts/gnome-contacts-46.0.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-46.0.ebuild
new file mode 100644
index 000000000000..0edf83222c9a
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-46.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+gnome-online-accounts"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	gnome-online-accounts? ( net-libs/gnome-online-accounts[vala] )
+	gnome-extra/evolution-data-server[gtk,vala]
+	>=dev-libs/libportal-0.6:=[gtk,vala]
+"
+RDEPEND="
+	>=dev-libs/folks-0.14.0:=[eds]
+	>=dev-libs/libgee-0.10:0.8=
+	>=dev-libs/glib-2.64:2
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.4_alpha:1
+	>=gnome-extra/evolution-data-server-3.42:=[gnome-online-accounts?]
+	>=dev-libs/libportal-0.6:=
+	>=media-gfx/qrencode-4.1.1:=
+	gnome-online-accounts? ( net-libs/gnome-online-accounts:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcamera=true # Ignored
+		-Dmanpage=true
+		-Ddocs=false
+		$(meson_use gnome-online-accounts goa)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}