[gentoo-commits] repo/gentoo:master commit in: dev-lang/gnuprologjava/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     1a7a73a2b483640de4d2bd4d3a33e5354b64a43a
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Tue Mar 12 15:36:02 2024 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Apr 25 05:51:19 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a7a73a2

dev-lang/gnuprologjava: switch to dev-java/ant

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/35724
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 .../gnuprologjava/gnuprologjava-0.2.6-r1.ebuild    | 46 ------------------
 .../gnuprologjava/gnuprologjava-0.2.6-r2.ebuild    | 54 ++++++++++++++++++++++
 2 files changed, 54 insertions(+), 46 deletions(-)

diff --git a/dev-lang/gnuprologjava/gnuprologjava-0.2.6-r1.ebuild b/dev-lang/gnuprologjava/gnuprologjava-0.2.6-r1.ebuild
deleted file mode 100644
index dbc6b257eff2..000000000000
--- a/dev-lang/gnuprologjava/gnuprologjava-0.2.6-r1.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 2016-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit java-pkg-2 java-ant-2
-
-DESCRIPTION="GNU Prolog for Java is an implementation of ISO Prolog as a Java library"
-HOMEPAGE="https://www.gnu.org/software/gnuprologjava"
-SRC_URI="mirror://gnu/gnuprologjava/${P}-src.zip"
-
-LICENSE="LGPL-3+"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="doc"
-
-BDEPEND="app-arch/unzip"
-RDEPEND=">=virtual/jdk-1.8:*"
-DEPEND="${RDEPEND}
-	dev-java/ant-core"
-
-S="${WORKDIR}"
-
-src_prepare() {
-	eapply "${FILESDIR}"/${P}-manual.patch
-	eapply_user
-}
-
-src_compile() {
-	eant jar
-	if use doc ; then
-		eant doc
-	fi
-	mv build/${P}.jar build/${PN}.jar || die
-}
-
-src_install() {
-	java-pkg_dojar build/${PN}.jar
-
-	if use doc ; then
-		java-pkg_dohtml -r build/api || die
-		java-pkg_dohtml -r build/manual || die
-	fi
-
-	dodoc NEWS.txt docs/readme.txt
-}

diff --git a/dev-lang/gnuprologjava/gnuprologjava-0.2.6-r2.ebuild b/dev-lang/gnuprologjava/gnuprologjava-0.2.6-r2.ebuild
new file mode 100644
index 000000000000..556d0c83474e
--- /dev/null
+++ b/dev-lang/gnuprologjava/gnuprologjava-0.2.6-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2016-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="GNU Prolog for Java is an implementation of ISO Prolog as a Java library"
+HOMEPAGE="https://www.gnu.org/software/gnuprologjava/"
+SRC_URI="mirror://gnu/gnuprologjava/${P}-src.zip"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+BDEPEND="app-arch/unzip"
+CP_DEPEND="dev-java/java-getopt:1"
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-1.8:*
+	doc? ( sys-apps/texinfo )"
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+DOCS=( NEWS.txt docs/readme.txt )
+PATCHES=( "${FILESDIR}/${P}-manual.patch" )
+
+JAVA_RESOURCE_DIRS="res"
+JAVA_SRC_DIR="src"
+
+src_prepare() {
+	default #780585
+	java-pkg-2_src_prepare
+	rm -r src/gnu/getopt || die
+	mkdir res || die
+	pushd src > /dev/null || die
+	find -type f \
+		! -name '*.java' \
+		| xargs cp --parent -t ../res || die
+	popd > /dev/null || die
+	if use doc; then
+		mkdir manual || die
+		makeinfo --html docs/manual.texinfo --output=manual
+	fi
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	if use doc; then
+		docinto html
+		dodoc -r manual || die
+	fi
+}