[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

["Marek Szuba" <marecki@gentoo.org>]

commit:     8a61302ae1775f3a6ea418b914a78e7943abb65e
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 24 13:04:52 2024 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Wed Apr 24 13:04:52 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8a61302a

sys-apps/fwupd: add 1.9.18

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 sys-apps/fwupd/Manifest            |   1 +
 sys-apps/fwupd/fwupd-1.9.18.ebuild | 210 +++++++++++++++++++++++++++++++++++++
 2 files changed, 211 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index e0b34873639d..6184fd621740 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,4 +1,5 @@
 DIST fwupd-1.9.10.tar.xz 3901816 BLAKE2B d8a0931188bf494e1b916f5bdebaf290b8e4b81a314e899f7b7e2aeec2dc37240b40c9fbf6259662fd2d92abca477460d630af0d8d95363027aa00ce46021789 SHA512 308bcd3af84d82157492a2ee8dc6fa4d7df6a66cca64e45b3dff9b46d0367f7d3122671388b627f67ab59a69bac1cb36feeccd1668cce0487fe466736dd8b8cc
 DIST fwupd-1.9.14.tar.xz 4367612 BLAKE2B d2e8ef60d751e56279428cd681769b8b6132148d87ad18beb8b355d10d03519da3d520f7f3f5a72b50591957b00176e80a4b26a472ed2305d39986b56adbbbc3 SHA512 582813ce5d61e10d0774195bc0e5abdf0f0ce103417df4a90a0c94ed6c124cd1bcad3118ba6f9f2054b156c0b85fc66edcbcced70dfefe616c2689257e8beeb1
 DIST fwupd-1.9.16.tar.xz 4284796 BLAKE2B 67f83826ed4978324777e737e2751f43454078b7d5e0165993572747c79465f128954c13ea39056483f9916a0b31cfd6800bea49c7bb50844a4df72d63d6ab09 SHA512 e373f17a8d946b07d6f299353949dfc503138c4198a87272018524a39598f3fbd8c381dd13d74469e296a143071cc9e739b3774d9eda8ae9557760fef0a02bb5
+DIST fwupd-1.9.18.tar.xz 4286880 BLAKE2B 7dd1691e2db600085a61a545961730a14d74e3f8b3a66fd90092658e19336a8e11861202db063d64c936cac9ab12ebf7dcdd3a8dcd7ff01b05f0a860d8b4ba68 SHA512 d5e0f3a8c741240f389628e2ed81f1e6ec21689bdcd39f692222114a2d495925a0f0720b10fbb0087362c0b734f4f0abfd8e105eff4695e41e645395e5587a50
 DIST fwupd-1.9.6.tar.xz 3863452 BLAKE2B 8b54efef5947dc4766a24b8501100f7e24707944b5c9aae3c3fcd88dfce230667507af8816203b0ececa0510485661f5f599c1cdc2285df72683ede4b7a6d15c SHA512 c65d795268e0e36fd2572ce3d4f2fb811412c16d583fa5463bee017a70b5d0f8b1b92460efa977a7d70bb5e3f6b5b02756e795e5f8ab7e7ac7874dc1ab5a0bfb

diff --git a/sys-apps/fwupd/fwupd-1.9.18.ebuild b/sys-apps/fwupd/fwupd-1.9.18.ebuild
new file mode 100644
index 000000000000..6553ff479810
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.9.18.ebuild
@@ -0,0 +1,210 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 vala udev xdg
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="amdgpu amt +archive bash-completion bluetooth cbor elogind fastboot flashrom gnutls gtk-doc +gusb introspection logitech lzma minimal modemmanager nvme policykit spi +sqlite synaptics systemd test test-full tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	fastboot? ( gusb )
+	logitech? ( gusb )
+	minimal? ( !introspection )
+	modemmanager? ( gusb )
+	spi? ( lzma )
+	synaptics? ( gnutls )
+	test? ( archive gusb )
+	test-full? ( test )
+	uefi? ( gnutls )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	$(python_gen_cond_dep '
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	>=dev-build/meson-0.60.0
+	virtual/pkgconfig
+	gtk-doc? (
+		$(python_gen_cond_dep '
+			>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+		')
+		>=dev-util/gi-docgen-2021.1
+	)
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	introspection? ( dev-libs/gobject-introspection )
+	test? (
+		net-libs/gnutls[tools]
+		test-full? ( dev-util/umockdev )
+	)
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/xz-utils
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/json-glib-1.6.0
+	>=dev-libs/libgudev-232:=
+	>=dev-libs/libjcat-0.1.4[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.3.6:=[introspection?]
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+	>=net-misc/curl-7.62.0
+	archive? ( app-arch/libarchive:= )
+	cbor? ( >=dev-libs/libcbor-0.7.0:= )
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( >=net-libs/gnutls-3.6.0 )
+	gusb? ( >=dev-libs/libgusb-0.3.8[introspection?] )
+	logitech? ( dev-libs/protobuf-c:= )
+	lzma? ( app-arch/xz-utils )
+	modemmanager? ( net-misc/modemmanager[mbim,qmi] )
+	policykit? ( >=sys-auth/polkit-0.114 )
+	sqlite? ( dev-db/sqlite )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss:= )
+	uefi? (
+		sys-apps/fwupd-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+	amdgpu? (
+		sys-kernel/linux-headers
+		x11-libs/libdrm[video_cards_amdgpu]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.9.6-fragile_tests.patch
+)
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		if use test-full && has sandbox ${FEATURES}; then
+			ewarn "Certain ${PN} tests are fragile with sandboxing enabled,"
+			ewarn "see https://github.com/fwupd/fwupd/issues/1414."
+			ewarn "When in doubt, emerge ${PN} with USE=-test-full."
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+
+	vala_setup
+
+	sed -e "/install_dir.*'doc'/s/doc/gtk-doc/" \
+		-i docs/meson.build || die
+
+	python_fix_shebang "${S}"/contrib/*.py
+}
+
+src_configure() {
+	local plugins=(
+		-Dplugin_gpio="enabled"
+		$(meson_feature amdgpu plugin_amdgpu)
+		$(meson_feature amt plugin_intel_me)
+		$(meson_feature fastboot plugin_fastboot)
+		$(meson_feature flashrom plugin_flashrom)
+		$(meson_feature gusb plugin_uf2)
+		$(meson_feature logitech plugin_logitech_bulkcontroller)
+		$(meson_feature modemmanager plugin_modem_manager)
+		$(meson_feature nvme plugin_nvme)
+		$(meson_use spi plugin_intel_spi)
+		$(meson_feature synaptics plugin_synaptics_mst)
+		$(meson_feature synaptics plugin_synaptics_rmi)
+		$(meson_feature tpm plugin_tpm)
+		$(meson_feature uefi plugin_uefi_capsule)
+		$(meson_use uefi plugin_uefi_capsule_splash)
+		$(meson_feature uefi plugin_uefi_pk)
+	)
+	if use ppc64 || use riscv ; then
+		plugins+=( -Dplugin_msr="disabled" )
+	fi
+
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		-Dconsolekit="disabled"
+		-Dcurl="enabled"
+		-Defi_binary="false"
+		-Dman="true"
+		-Dsupported_build="enabled"
+		-Dsystemd_unit_user=""
+		-Dudevdir="${EPREFIX}$(get_udevdir)"
+		$(meson_feature archive libarchive)
+		$(meson_use bash-completion bash_completion)
+		$(meson_feature bluetooth bluez)
+		$(meson_feature cbor)
+		$(meson_feature elogind)
+		$(meson_feature gnutls)
+		$(meson_feature gtk-doc docs)
+		$(meson_feature gusb)
+		$(meson_feature lzma)
+		$(meson_feature introspection)
+		$(meson_feature policykit polkit)
+		$(meson_feature sqlite)
+		$(meson_feature systemd)
+		$(meson_use test tests)
+		$(meson_use test-full)
+
+		${plugins[@]}
+	)
+	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_test() {
+	LC_ALL="C" meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
+	fi
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -rf \
+			"${ED}"/usr/libexec/installed-tests \
+			"${ED}"/usr/share/fwupd/device-tests \
+			"${ED}"/usr/share/fwupd/host-emulate.d/thinkpad-p1-iommu.json.gz \
+			"${ED}"/usr/share/fwupd/remotes.d/fwupd-tests.conf \
+			"${ED}"/usr/share/installed-tests \
+		|| die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	use minimal || udev_reload
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	use minimal || udev_reload
+}