[gentoo-commits] repo/gentoo:master commit in: media-libs/libepoxy/

["Matt Turner" <mattst88@gentoo.org>]

commit:     e0a1a43dab801e160832a874c8d305e88956943a
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 21 22:33:18 2024 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Apr 21 22:40:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0a1a43d

media-libs/libepoxy: Revbump

Closes: https://bugs.gentoo.org/930239
Closes: https://bugs.gentoo.org/919911
Closes: https://bugs.gentoo.org/929993
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-libs/libepoxy/libepoxy-1.5.10-r3.ebuild | 54 +++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/media-libs/libepoxy/libepoxy-1.5.10-r3.ebuild b/media-libs/libepoxy/libepoxy-1.5.10-r3.ebuild
new file mode 100644
index 000000000000..2abe9d8c340e
--- /dev/null
+++ b/media-libs/libepoxy/libepoxy-1.5.10-r3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE='xml(+)'
+inherit meson-multilib python-any-r1 virtualx
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/anholt/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/anholt/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Library for handling OpenGL function pointer management"
+HOMEPAGE="https://github.com/anholt/libepoxy"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test +X"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	media-libs/libglvnd[X?,${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	X? (
+		x11-base/xorg-proto
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}"/libepoxy-1.5.10-libopengl-fallback.patch )
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Degl=yes
+		-Dglx=$(usex X)
+		$(meson_use X x11)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	virtx meson_src_test
+}