[gentoo-commits] repo/gentoo:master commit in: dev-libs/libei/

["Matt Turner" <mattst88@gentoo.org>]

commit:     fe56e06c2c47c5e19fb8ad0f044cb4b84c82cffa
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 21 21:05:02 2024 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Apr 21 21:05:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fe56e06c

dev-libs/libei: Drop old versions

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libei/Manifest           |  1 -
 dev-libs/libei/libei-1.2.0.ebuild | 98 ---------------------------------------
 2 files changed, 99 deletions(-)

diff --git a/dev-libs/libei/Manifest b/dev-libs/libei/Manifest
index 50c1bf564d9b..14d671e41b99 100644
--- a/dev-libs/libei/Manifest
+++ b/dev-libs/libei/Manifest
@@ -1,3 +1,2 @@
-DIST libei-1.2.0.tar.bz2 174155 BLAKE2B 4b540cb79decd9785f67efa6fa76b984eb7ae2729dd49ac36e240b6a4feb4c54b34626dad93831c873861e3d3fd597c530e7eaaab0150890f0c952a9d75ee178 SHA512 c1d39c2c830df373ff5d7cc3eca330c2d771a26df6f2902d62f639a8a4db9af5370db4b9defe605721dd1f429eae68cbc4249792b3ae26b4c82d269f07a36732
 DIST libei-1.2.1.tar.bz2 174636 BLAKE2B b718d2287e83adb43a8dee9ae06499d780b2a50231e9ce452b6e7bfa9e89e9599058628614fb4325d0cef842d6b29ca68eb38b3e547790cd5a7a0ac14728f250 SHA512 ac8e32a381b9555a6b9becab9217a323d79aeba4b3f11e1dbba9f876d566f232f41d0f299f8cb8e5de6707d0dd91e93872edd81532c971e35d1cf33f9f9063b4
 DIST munit-fbbdf1467eb0d04a6ee465def2e529e4c87f2118.tar.gz 27724 BLAKE2B 9670c9b7a0b5d9ee6ec8df2dea9e241b043964ecf1fa3f6060ad1d16c40ab6afe47f53c6d4a791003e101a0b363263b858e6e4e445f868292753dd1ee7f7e3ce SHA512 26b5599fd12be627a692823ebf496fa446be7ed04a1233fb42e0667c05109b0f804f76646e289ac660fc815baf45f77ec8caf0ff2ea7fb0b4f87f0038a2b971c

diff --git a/dev-libs/libei/libei-1.2.0.ebuild b/dev-libs/libei/libei-1.2.0.ebuild
deleted file mode 100644
index 6959da0ea131..000000000000
--- a/dev-libs/libei/libei-1.2.0.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-inherit meson python-any-r1
-
-DESCRIPTION="Library for Emulated Input, primarily aimed at the Wayland stack"
-HOMEPAGE="https://gitlab.freedesktop.org/libinput/libei"
-SRC_URI="https://gitlab.freedesktop.org/libinput/${PN}/-/archive/${PV}/${P}.tar.bz2"
-MUNIT_COMMIT="fbbdf1467eb0d04a6ee465def2e529e4c87f2118"
-SRC_URI+=" https://github.com/nemequ/munit/archive/${MUNIT_COMMIT}.tar.gz -> munit-${MUNIT_COMMIT}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
-IUSE="elogind systemd test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-libs/libevdev-1.9.902
-	|| (
-		systemd? ( >=sys-apps/systemd-237 )
-		elogind? ( >=sys-auth/elogind-237 )
-		sys-libs/basu
-	)
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	$(python_gen_any_dep '
-		dev-python/attrs[${PYTHON_USEDEP}]
-		dev-python/jinja[${PYTHON_USEDEP}]
-	')
-	test? (
-		$(python_gen_any_dep '
-			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/python-dbusmock[${PYTHON_USEDEP}]
-			dev-python/pyyaml[${PYTHON_USEDEP}]
-			dev-python/structlog[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-python_check_deps() {
-	if use test; then
-		python_has_version \
-			"dev-python/pytest[${PYTHON_USEDEP}]" \
-			"dev-python/python-dbusmock[${PYTHON_USEDEP}]" \
-			"dev-python/pyyaml[${PYTHON_USEDEP}]" \
-			"dev-python/structlog[${PYTHON_USEDEP}]" \
-			|| return 1
-	fi
-	python_has_version \
-		"dev-python/attrs[${PYTHON_USEDEP}]" \
-		"dev-python/jinja[${PYTHON_USEDEP}]" \
-		|| return 1
-}
-
-src_unpack() {
-	if [[ -n ${A} ]]; then
-		unpack ${A}
-		mv "${WORKDIR}"/munit-${MUNIT_COMMIT} "${WORKDIR}"/${P}/subprojects/munit || die
-		rm "${WORKDIR}"/${P}/subprojects/munit.wrap || die
-	fi
-}
-
-src_prepare() {
-	default
-
-	sed -i -e 's:^valgrind = .*:valgrind = disabler():g' test/meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		-Ddocumentation=""
-		-Dliboeffis=enabled
-		$(meson_feature test tests)
-	)
-	if use systemd; then
-		emesonargs+=(-Dsd-bus-provider=libsystemd)
-	elif use elogind; then
-		emesonargs+=(-Dsd-bus-provider=libelogind)
-	else
-		emesonargs+=(-Dsd-bus-provider=basu)
-	fi
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	# munit subproject is installed but not wanted
-	if use test; then
-		rm "${ED}"/usr/lib*/libmunit.so || die
-	fi
-}