[gentoo-commits] repo/gentoo:master commit in: dev-libs/apache-arrow/

["Michał Górny" <mgorny@gentoo.org>]

commit:     3d2d9fe4fc6f00ad6a24b92c363fa3022dba1d42
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 21 01:46:53 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Apr 21 02:35:05 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d2d9fe4

dev-libs/apache-arrow: Bump to 16.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-libs/apache-arrow/Manifest                   |   3 +
 dev-libs/apache-arrow/apache-arrow-16.0.0.ebuild | 131 +++++++++++++++++++++++
 2 files changed, 134 insertions(+)

diff --git a/dev-libs/apache-arrow/Manifest b/dev-libs/apache-arrow/Manifest
index e2fb27f2e2eb..c705712fbd3c 100644
--- a/dev-libs/apache-arrow/Manifest
+++ b/dev-libs/apache-arrow/Manifest
@@ -1,3 +1,6 @@
 DIST apache-arrow-15.0.2.tar.gz 21503812 BLAKE2B 5a42b3409515d7a09daff33d30e72e828e1df2e009ed746f101f4d8e6dcadb2e9c305a6cb9799d4003e1421ba666d2a2e9ba182c11b0c538fbd1aee4b3ba10ff SHA512 6c83e3be1e5840c30387f088315b74aca8e7c2d060793af70a156effb496a71e3e6af0693188c0f46f8a4a061a263a47095912ef04a5dc8141abd59075b14c78
+DIST apache-arrow-16.0.0.tar.gz 21695067 BLAKE2B aa5dfef3d8d46a53242075c165473635051d51ff28587ea8b80751232d5f75ee3ef89e0a027aa39bdc9dc03fa46ddb68e46ae2c7f40605258e47ff194f1d3979 SHA512 773f4f3eef603032c8ba0cfdc023bfd2a24bb5e41c82da354a22d7854ab153294ede1f4782cc32b27451cf1b58303f105bac61ceeb3568faea747b93e21d79e4
+DIST apache-arrow-arrow-data-25d16511e8d42c2744a1d94d90169e3a36e92631.tar.gz 3571960 BLAKE2B c1c076bb3ff6427a45d1a157c60fb13c37786f97d213768c0bbe1ae073b5fb8d23cd402bdcfee303061df56bf3421ea8376f7c4ba9fec04c5cb35a85a32280f2 SHA512 abbc18da8f03b123a2d97eee709e929bbb5d567bf23219bbc63508c0e82ef99d7c0d71ca2d952566b63e968cffd96c5e1c62be9cb658323c949f229ff03234a8
 DIST apache-arrow-arrow-data-ad82a736c170e97b7c8c035ebd8a801c17eec170.tar.gz 3571641 BLAKE2B e3daae62938b54dbeb8ca9227eddfd2d59864cfafb54a7a7fd7aaa2b2cabd0f2dde58b77b2def086a1759b43c3b5834cb55462cc0b2886b2892329a957afdacb SHA512 ad6fd3343d8a3a6beb5b6269815bc207171905c102698fdb8ed7091e6d829dc51f354293c7686f845e3d49c4a828d9c77958447d965c9da4272260984fea4262
+DIST apache-arrow-parquet-data-74278bc4a1122d74945969e6dec405abd1533ec3.tar.gz 1037654 BLAKE2B c9bb725a16f6706a3859bb36a60b700af62cb5f96546483ef1de0b65900b02b4f9013841d7b3dc70fd0f2fd8969b4d5c72d0fb68972568f61b4a6863a0df6f60 SHA512 18f8e2480079a0fd29eec2b8e5f753af1ee80255f6fc80af4acbf5c56e6dec08e2f9f54d8c5734c929ef901c63e4009c5d830325333fa6cc947d40ff5dcddfa3
 DIST apache-arrow-parquet-data-d69d979223e883faef9dc6fe3cf573087243c28a.tar.gz 1022547 BLAKE2B a36f950160a6e033c0ab4fb9ac391be6e71cdadf2bbb7d0210640cc41782921b0e0777425b811a1d688e03842684eb1bfe008ffe359b182bea0f80d3adf658fe SHA512 dfebeca5b99a72a4c069c1030102a6fdd35d4c58cb12fb640bcd0a623cc54e49363f1112fa45da14b16867630dc30bc94bdb2e4cc95f9379dcaa5d7f8f38a3ea

diff --git a/dev-libs/apache-arrow/apache-arrow-16.0.0.ebuild b/dev-libs/apache-arrow/apache-arrow-16.0.0.ebuild
new file mode 100644
index 000000000000..9be18f6b6223
--- /dev/null
+++ b/dev-libs/apache-arrow/apache-arrow-16.0.0.ebuild
@@ -0,0 +1,131 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+# arrow.git: testing
+ARROW_DATA_GIT_HASH=25d16511e8d42c2744a1d94d90169e3a36e92631
+# arrow.git: cpp/submodules/parquet-testing
+PARQUET_DATA_GIT_HASH=74278bc4a1122d74945969e6dec405abd1533ec3
+
+DESCRIPTION="A cross-language development platform for in-memory data."
+HOMEPAGE="
+	https://arrow.apache.org/
+	https://github.com/apache/arrow/
+"
+SRC_URI="
+	mirror://apache/arrow/arrow-${PV}/${P}.tar.gz
+	test? (
+		https://github.com/apache/parquet-testing/archive/${PARQUET_DATA_GIT_HASH}.tar.gz
+			-> ${PN}-parquet-data-${PARQUET_DATA_GIT_HASH}.tar.gz
+		https://github.com/apache/arrow-testing/archive/${ARROW_DATA_GIT_HASH}.tar.gz
+			-> ${PN}-arrow-data-${ARROW_DATA_GIT_HASH}.tar.gz
+	)
+"
+S="${WORKDIR}/${P}/cpp"
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~riscv ~s390 ~x86"
+IUSE="
+	+brotli bzip2 compute dataset +json lz4 +parquet re2 +snappy ssl
+	test zlib zstd
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	brotli? ( app-arch/brotli:= )
+	bzip2? ( app-arch/bzip2:= )
+	compute? ( dev-libs/libutf8proc:= )
+	dataset? (
+		dev-libs/libutf8proc:=
+	)
+	lz4? ( app-arch/lz4:= )
+	parquet? (
+		dev-libs/libutf8proc:=
+		dev-libs/thrift:=
+		ssl? ( dev-libs/openssl:= )
+	)
+	re2? ( dev-libs/re2:= )
+	snappy? ( app-arch/snappy:= )
+	zlib? ( sys-libs/zlib:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/xsimd
+	>=dev-libs/boost-1.81.0
+	json? ( dev-libs/rapidjson )
+	test? (
+		dev-cpp/gflags
+		dev-cpp/gtest
+	)
+"
+
+REQUIRED_USE="
+	test? (
+		json
+		parquet? ( zstd )
+	)
+	ssl? ( json )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-11.0.0-shared-lz4.patch"
+)
+
+src_prepare() {
+	# use Gentoo CXXFLAGS, specify docdir at src_configure.
+	sed -i \
+		-e '/SetupCxxFlags/d' \
+		-e '/set(ARROW_DOC_DIR.*)/d' \
+		CMakeLists.txt \
+		|| die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DARROW_BUILD_STATIC=OFF
+		-DARROW_BUILD_TESTS=$(usex test)
+		-DARROW_COMPUTE=$(usex compute)
+		-DARROW_CSV=ON
+		-DARROW_DATASET=$(usex dataset)
+		-DARROW_DEPENDENCY_SOURCE=SYSTEM
+		-DARROW_DOC_DIR=share/doc/${PF}
+		-DARROW_FILESYSTEM=ON
+		-DARROW_HDFS=ON
+		-DARROW_JEMALLOC=OFF
+		-DARROW_JSON=$(usex json)
+		-DARROW_PARQUET=$(usex parquet)
+		-DPARQUET_REQUIRE_ENCRYPTION=$(usex ssl)
+		-DARROW_USE_CCACHE=OFF
+		-DARROW_USE_SCCACHE=OFF
+		-DARROW_WITH_BROTLI=$(usex brotli)
+		-DARROW_WITH_BZ2=$(usex bzip2)
+		-DARROW_WITH_LZ4=$(usex lz4)
+		-DARROW_WITH_RE2=$(usex re2)
+		-DARROW_WITH_SNAPPY=$(usex snappy)
+		-DARROW_WITH_ZLIB=$(usex zlib)
+		-DARROW_WITH_ZSTD=$(usex zstd)
+		-DCMAKE_CXX_STANDARD=17
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	export PARQUET_TEST_DATA="${WORKDIR}/parquet-testing-${PARQUET_DATA_GIT_HASH}/data"
+	export ARROW_TEST_DATA="${WORKDIR}/arrow-testing-${ARROW_DATA_GIT_HASH}/data"
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+	if use test; then
+		cd "${D}"/usr/$(get_libdir) || die
+		rm -r cmake/ArrowTesting || die
+		rm libarrow_testing* || die
+		rm pkgconfig/arrow-testing.pc || die
+	fi
+}