[gentoo-commits] repo/gentoo:master commit in: dev-python/nautilus-python/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     1506c471a93301b1c3617c9187dd74c7b4cf20d0
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 20 14:21:10 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Apr 20 14:36:17 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1506c471

dev-python/nautilus-python: add 4.0.1

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-python/nautilus-python/Manifest                |  1 +
 .../nautilus-python/nautilus-python-4.0.1.ebuild   | 52 ++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-python/nautilus-python/Manifest b/dev-python/nautilus-python/Manifest
index e561fe591e12..26b2dff5b382 100644
--- a/dev-python/nautilus-python/Manifest
+++ b/dev-python/nautilus-python/Manifest
@@ -1 +1,2 @@
+DIST nautilus-python-4.0.1.tar.xz 32236 BLAKE2B 822812ac86bbfa9e3978468968ec9291cf2f95ab4954cffeebe62f4d297b5816ad1a59cf04bbc31a146c0858e45509a4b5988789f17e7b76c4221e9c6fb1e285 SHA512 24e64af1c1cb8c70a4ea53bb064baf681d8848b2e8b549f682913a4883260b3f2384f985285d17e03736e414503ab82ea79bade9bcbe482a2cbecbb0a8356cea
 DIST nautilus-python-4.0.tar.xz 32184 BLAKE2B cc910de82e54cd687d23541a0b283a70dc5a0626acebf8787110ae1b5a4c080741c0879968816e217a4da968a77169d79b6614dd055f1ae57999a9a49f2553cb SHA512 f70f825b821f266caafd1b347066de01462b8256ec126072042d09dd7fd6c9324847d5ddab65671589d0a411f8b8fed428dbc94806ac679d646861c66c3a0dd5

diff --git a/dev-python/nautilus-python/nautilus-python-4.0.1.ebuild b/dev-python/nautilus-python/nautilus-python-4.0.1.ebuild
new file mode 100644
index 000000000000..e0bbb753f23b
--- /dev/null
+++ b/dev-python/nautilus-python/nautilus-python-4.0.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome2 meson python-single-r1
+
+DESCRIPTION="Python bindings for the Nautilus file manager"
+HOMEPAGE="https://projects.gnome.org/nautilus-python/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="gtk-doc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Require pygobject:3 and USE=introspection on nautilus for sanity,
+# because no (user) plugins could work without them; meson.build
+# requires pygobject:3 and >=nautilus-43.0
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=gnome-base/nautilus-43.0[introspection]
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( dev-util/gtk-doc )
+	>=dev-build/gtk-doc-am-1.14
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gtk-doc docs)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}/usr/share/doc/${PN}/"* "${ED}/usr/share/doc/${P}" || die
+	rm -d "${ED}/usr/share/doc/${PN}" || die
+
+	# Directory for systemwide extensions
+	keepdir /usr/share/nautilus-python/extensions
+}