[gentoo-commits] repo/gentoo:master commit in: sci-visualization/pythonprop/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     0530fd355d41119406a4d8c0fff16024c0e62724
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 19 15:13:13 2024 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Fri Apr 19 15:13:45 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0530fd35

sci-visualization/pythonprop: Add support for Python3.12

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 .../pythonprop/pythonprop-0.30.1-r1.ebuild         | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/sci-visualization/pythonprop/pythonprop-0.30.1-r1.ebuild b/sci-visualization/pythonprop/pythonprop-0.30.1-r1.ebuild
new file mode 100644
index 000000000000..0020e216326c
--- /dev/null
+++ b/sci-visualization/pythonprop/pythonprop-0.30.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Scripts to prepare and plot VOACAP propagation predictions"
+HOMEPAGE="https://www.qsl.net/h/hz1jw/pythonprop"
+SRC_URI="https://github.com/jawatson/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	')
+	dev-python/cairocffi
+	sci-libs/cartopy[${PYTHON_SINGLE_USEDEP}]
+	sci-electronics/voacapl
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+"
+
+PATCHES=( "${FILESDIR}/${PN}-drop-portland.patch" )
+
+src_prepare() {
+	eapply_user
+
+	eapply ${PATCHES[@]}
+
+	# drop building *.pdf files
+	sed -i -e "s#docs/user/help##g" Makefile.am || die
+	# do not call update_destop_database here
+	sed -ie "s/UPDATE_DESKTOP = /UPDATE_DESKTOP = # /g" data/Makefile.am || die
+	# fix Desktop Entry
+	sed -ie "s/HamRadio/HamRadio;/g" data/voacapgui.desktop.in || die
+	eautoreconf
+}
+
+src_install() {
+	default
+	python_optimize
+}