[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel/

["Michał Górny" <mgorny@gentoo.org>]

commit:     faa359ccbac0e49522d844477584c2343af0e432
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 18 12:26:11 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Apr 18 15:45:25 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=faa359cc

sys-kernel/gentoo-kernel: Bump to 6.1.87

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-kernel/gentoo-kernel/Manifest                  |   2 +
 .../gentoo-kernel/gentoo-kernel-6.1.87.ebuild      | 146 +++++++++++++++++++++
 2 files changed, 148 insertions(+)

diff --git a/sys-kernel/gentoo-kernel/Manifest b/sys-kernel/gentoo-kernel/Manifest
index 36ac40114cc6..49d12b9a922a 100644
--- a/sys-kernel/gentoo-kernel/Manifest
+++ b/sys-kernel/gentoo-kernel/Manifest
@@ -18,6 +18,8 @@ DIST genpatches-6.1-94.base.tar.xz 5046684 BLAKE2B f9024ee9302b618af0e68c4b0ed91
 DIST genpatches-6.1-94.extras.tar.xz 3816 BLAKE2B 1f542b22b91ed285938cfbc6eef5f6ebce579882f65cfd7031b38aedbc3fdbe88abefec221e3139f3ea44c9a7841283d733f4a21ac3c4e449273e4269a491692 SHA512 035461792175f6914813dd900c1ab18a93998d7a54f42cd15275e23fb1e0c6b76382e3dd9782f50aaea9eceb1271518918bac964f95db2d746f3deb0a9a0dc1d
 DIST genpatches-6.1-95.base.tar.xz 5062256 BLAKE2B e08c254f1e2e2a062d2b8026109d72553ca8083b170f0a4424c78ac53802bd5bf54d23195dd89f748ef6c253bdf1058cdd65a6f548d0b0a5378b8636b63c3908 SHA512 0607276c857bd40a96e74fafea00d11c0ac80a3801a3cb320230463be1f6ad52727f0081261194a6fff1b0d644b3561663eb51cb3c36778c5827b5859e0923d6
 DIST genpatches-6.1-95.extras.tar.xz 3816 BLAKE2B b1fd3b8c0cfdf227a96084fb8eb2ac99d9ff5d45bc3b3092818accd4253e677cb4962e7a554d3510a3bdc62dcad9b7ae22f549f15e0478241fa2c6d19a45da97 SHA512 73f46044c7d64969a287cbb269c9039bb1eb1d537fb1cdcfe0bc3772b9fa220419abda8ef5395d3d0d06ca80d3761a6eda610251cc825b79fc7fa3b4b0c1cd99
+DIST genpatches-6.1-96.base.tar.xz 5079348 BLAKE2B 97ea3473a5189a92ea4478ff82051fb6b9b48344284168902c98674f4d093e2d9e8deaafc5e6ffdfe4653c7aa41bacb5c094f867dba3e283bf2fbb236d753d80 SHA512 3e7f9a56a0767b7532c89460c156d663e2bed069223c27f7b6d5ca7084c3ee869b00bd63a844989c4801e29e442ddf7889c4a025af97195228e181564d8f087e
+DIST genpatches-6.1-96.extras.tar.xz 3812 BLAKE2B 506642a22002bf8bd3607d2bf060740e29d1a6bb649b0345f751c83e504f1084bf0bf279e69c7f52fae517acd7b166c32861f5263d843a02384d12b7f6e04e9c SHA512 1c5a7f9e3f28d2db1d0136a037d32c30cfe754186491970addb9f3b8d24bad851e9472c028e6eb8dcc71bf892a227d7a7e606fa7b7210cf11f79b6d8a063617a
 DIST genpatches-6.6-27.base.tar.xz 1392292 BLAKE2B 46e3c354f7c27182c2f97bd20c165fa8bb79317bb136afbbe1e0906cd405e7cbcab1293e724cda38491f0d1cd9e9009146f18ad9b5ecf54526e69aae43fbc9e8 SHA512 363d26f9410e2d526f07c0831d36733999ec284ee01d684ad15aa5856b007a2d2a189ca414358da87a479dcbbea7ae24add9d8019b4c41c8bf1aae7b67a3b490
 DIST genpatches-6.6-27.extras.tar.xz 3700 BLAKE2B 36a21c970dd2c8f72a4496b9f72faea3e94fba49342e00b7cdfc0ca6d4f3ab14fef161a7d02ad13b1c7db73af3c96b1c145453d0645791b46b34f599b3947582 SHA512 996a1b0a5c625043ececbeacc648f4dd71da2e239482ca515b680b146ba6041feeb0924929b1b2b6ee4f3ecc24c85926e54e28058d9401d4399282151332dfce
 DIST genpatches-6.6-32.base.tar.xz 1799112 BLAKE2B a9c9af39b7da19c0d3f3a1893de26641b1d5d7ad242de4ceb1659d33573e8df8d173d363f005843149ee21598a2d4f8a6e5fbbdd02926c23cccc01a5c0b8abcc SHA512 2204a3ff6187c349a41f101bddffd39145aa530e6a37792b391db0b3c4150e290ce8909430e87c8deb18400d753a621b90c26d581c08abf104a8bc48197a1fe6

diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-6.1.87.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-6.1.87.ebuild
new file mode 100644
index 000000000000..bd854e7fc50f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-6.1.87.ebuild
@@ -0,0 +1,146 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-build toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 9 ))
+# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
+# forked to https://github.com/projg2/fedora-kernel-config-for-gentoo
+CONFIG_VER=6.1.7-gentoo
+GENTOO_CONFIG_VER=g11
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="
+	https://wiki.gentoo.org/wiki/Project:Distribution_Kernel
+	https://www.kernel.org/
+"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	https://github.com/projg2/gentoo-kernel-config/archive/${GENTOO_CONFIG_VER}.tar.gz
+		-> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
+	amd64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-x86_64-fedora.config
+			-> kernel-x86_64-fedora.config.${CONFIG_VER}
+	)
+	arm64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-aarch64-fedora.config
+			-> kernel-aarch64-fedora.config.${CONFIG_VER}
+	)
+	ppc64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-ppc64le-fedora.config
+			-> kernel-ppc64le-fedora.config.${CONFIG_VER}
+	)
+	x86? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-i686-fedora.config
+			-> kernel-i686-fedora.config.${CONFIG_VER}
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="debug hardened"
+REQUIRED_USE="
+	arm? ( savedconfig )
+	hppa? ( savedconfig )
+	riscv? ( savedconfig )
+	sparc? ( savedconfig )
+"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel-bin:${SLOT}
+"
+BDEPEND="
+	debug? ( dev-util/pahole )
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+
+QA_FLAGS_IGNORED="
+	usr/src/linux-.*/scripts/gcc-plugins/.*.so
+	usr/src/linux-.*/vmlinux
+	usr/src/linux-.*/arch/powerpc/kernel/vdso.*/vdso.*.so.dbg
+"
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	default
+
+	local biendian=false
+
+	# prepare the default config
+	case ${ARCH} in
+		amd64)
+			cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		arm)
+			return
+			;;
+		arm64)
+			cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		hppa)
+			return
+			;;
+		ppc)
+			# assume powermac/powerbook defconfig
+			# we still package.use.force savedconfig
+			cp "${WORKDIR}/${MY_P}/arch/powerpc/configs/pmac32_defconfig" .config || die
+			;;
+		ppc64)
+			cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		riscv)
+			return
+			;;
+		sparc)
+			return
+			;;
+		x86)
+			cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	local myversion="-gentoo-dist"
+	use hardened && myversion+="-hardened"
+	echo "CONFIG_LOCALVERSION=\"${myversion}\"" > "${T}"/version.config || die
+	local dist_conf_path="${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"
+
+	local merge_configs=(
+		"${T}"/version.config
+		"${dist_conf_path}"/base.config
+	)
+	use debug || merge_configs+=(
+		"${dist_conf_path}"/no-debug.config
+	)
+	if use hardened; then
+		merge_configs+=( "${dist_conf_path}"/hardened-base.config )
+
+		tc-is-gcc && merge_configs+=( "${dist_conf_path}"/hardened-gcc-plugins.config )
+
+		if [[ -f "${dist_conf_path}/hardened-${ARCH}.config" ]]; then
+			merge_configs+=( "${dist_conf_path}/hardened-${ARCH}.config" )
+		fi
+	fi
+
+	# this covers ppc64 and aarch64_be only for now
+	if [[ ${biendian} == true && $(tc-endian) == big ]]; then
+		merge_configs+=( "${dist_conf_path}/big-endian.config" )
+	fi
+
+	kernel-build_merge_configs "${merge_configs[@]}"
+}