[gentoo-commits] repo/gentoo:master commit in: x11-libs/libxcb/

["Matt Turner" <mattst88@gentoo.org>]

commit:     6e4408ce383c4a041baf120c14465f4f50c2a42a
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 15 15:19:49 2024 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Apr 15 15:32:46 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6e4408ce

x11-libs/libxcb: Version bump to 1.17.0

Closes: https://bugs.gentoo.org/913655
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 x11-libs/libxcb/Manifest             |  1 +
 x11-libs/libxcb/libxcb-1.17.0.ebuild | 56 ++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/x11-libs/libxcb/Manifest b/x11-libs/libxcb/Manifest
index dc1d2bbb7b2c..7592b177c19a 100644
--- a/x11-libs/libxcb/Manifest
+++ b/x11-libs/libxcb/Manifest
@@ -1,2 +1,3 @@
 DIST libxcb-1.16.1.tar.xz 455368 BLAKE2B 91d489eaf8b0bfb0c02a4d974f72871963dc86cdf60478d618636d580974b260ab822ab33c7174e05dc45adf01e53e423a7449550b7b43fabb3917f7d99219c0 SHA512 e3afdae1c0e2a5ae2add7b2c4fdd3283cb86023ef6448f5b8b29a4bb72c274e34eaf0fc7523762bcd3f5116910fe7374490e8f26c25744301563ced80acc3e7f
 DIST libxcb-1.16.tar.xz 452964 BLAKE2B 1ddd5c2e6be8400a0a77db4b5fbd4698996fd1a00984e370b1f712f6b9ce456c8ccfb6992f2973f5eaf8d5b6b75f39b9f51a1458c2432ddb41edd8199b91b3f9 SHA512 002fbc126c6f09eb7db5e4197cd0572d495f64b6de714a76d9a024fe3e13122c1cfc7c55207c0dee76cc63fcccf87b37db513223eadaf760af2bd2a926443bf8
+DIST libxcb-1.17.0.tar.xz 455208 BLAKE2B e2a35606981c00f9f18e5590cdc26c7c2efd8f832c37dc4dc82db47e2870bf4ff48786162c5a8eb713cb5f3a305eb22d334e4b0ff631bf0e047f1b79cb0701d3 SHA512 945b1f28e8b407a4d0ebf88c99ef3cbef763fd75e6eaa8e971946e44ce8dbe9b478c56ae85aaaadab7fdb25987e88570d9d4fb9ad2febd6d6bf21d644a0e10d0

diff --git a/x11-libs/libxcb/libxcb-1.17.0.ebuild b/x11-libs/libxcb/libxcb-1.17.0.ebuild
new file mode 100644
index 000000000000..e28a1fa98c30
--- /dev/null
+++ b/x11-libs/libxcb/libxcb-1.17.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="xml(+)"
+
+XORG_TARBALL_SUFFIX="xz"
+XORG_MULTILIB=yes
+XORG_DOC=doc
+
+inherit python-any-r1 xorg-3
+
+DESCRIPTION="X C-language Bindings library"
+HOMEPAGE="https://xcb.freedesktop.org/ https://gitlab.freedesktop.org/xorg/lib/libxcb"
+
+SLOT="0/1.12"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc selinux test +xkb"
+RESTRICT="!test? ( test )"
+
+XCB_PROTO_DEP=">=x11-base/xcb-proto-${PV}"
+RDEPEND="
+	>=x11-libs/libXau-1.0.7-r1[${MULTILIB_USEDEP}]
+	>=x11-libs/libXdmcp-1.1.1-r1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	${XCB_PROTO_DEP}
+	elibc_Darwin? ( dev-libs/libpthread-stubs )
+	test? ( dev-libs/check[${MULTILIB_USEDEP}] )
+"
+# Note: ${PYTHON_USEDEP} needs to go verbatim
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep "${XCB_PROTO_DEP}"'[${PYTHON_USEDEP}]')
+	doc? ( app-text/doxygen[dot] )
+	test? ( dev-libs/libxslt )
+"
+
+python_check_deps() {
+	python_has_version "${XCB_PROTO_DEP}[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	xorg-3_pkg_setup
+}
+
+src_configure() {
+	local XORG_CONFIGURE_OPTIONS=(
+		$(use_enable doc devel-docs)
+		$(use_enable selinux)
+	)
+	xorg-3_src_configure
+}