[gentoo-commits] repo/gentoo:master commit in: dev-libs/libunique/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     afa7628b490c279f84a9e02b0d2ef773ff5f0597
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 11 18:29:48 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Apr 11 18:29:48 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=afa7628b

dev-libs/libunique: EAPI8 for SLOT=1 and SLOT=3

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-libs/libunique/libunique-1.1.6-r3.ebuild | 65 ++++++++++++++++++++++++++++
 dev-libs/libunique/libunique-3.0.2-r2.ebuild | 46 ++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/dev-libs/libunique/libunique-1.1.6-r3.ebuild b/dev-libs/libunique/libunique-1.1.6-r3.ebuild
new file mode 100644
index 000000000000..0d8a90e831d9
--- /dev/null
+++ b/dev-libs/libunique/libunique-1.1.6-r3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GNOME2_LA_PUNT="yes"
+GNOME_TARBALL_SUFFIX="bz2"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="A library for writing single instance application"
+HOMEPAGE="https://wiki.gnome.org/Attic/LibUnique"
+
+LICENSE="LGPL-2.1"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug dbus +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.12:2
+	>=x11-libs/gtk+-2.11:2[introspection?]
+	x11-libs/libX11
+	dbus? (
+		>=dev-libs/dbus-glib-0.70
+		sys-apps/dbus[X]
+	)
+	introspection? ( >=dev-libs/gobject-introspection-0.6.3:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-build/gtk-doc-am-1.11
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# For eautoreconf
+#	dev-build/gtk-doc-am
+
+PATCHES=(
+	# Include NUL terminator in unique_message_data_get_filename()
+	"${FILESDIR}/${P}-include-terminator.patch"
+
+	# test-unique: Resolve format string issues
+	"${FILESDIR}/${P}-fix-test.patch"
+
+	# Remove compiler warnings
+	"${FILESDIR}/${P}-compiler-warnings.patch"
+
+	# Remove G_CONST_RETURN usage, now that its gone in glib
+	"${FILESDIR}/${PN}-1.1.6-G_CONST_RETURN.patch"
+)
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-maintainer-flags \
+		--enable-bacon \
+		$(use_enable introspection) \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable dbus)
+}
+
+src_test() {
+	cd "${S}/tests" || die
+	cp "${FILESDIR}/run-tests" . || die "Unable to cp \${FILESDIR}/run-tests"
+	virtx emake -f run-tests
+}

diff --git a/dev-libs/libunique/libunique-3.0.2-r2.ebuild b/dev-libs/libunique/libunique-3.0.2-r2.ebuild
new file mode 100644
index 000000000000..91a4162448a3
--- /dev/null
+++ b/dev-libs/libunique/libunique-3.0.2-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="A library for writing single instance application"
+HOMEPAGE="https://wiki.gnome.org/Attic/LibUnique"
+
+LICENSE="LGPL-2.1"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.25.7:2
+	sys-apps/dbus[X]
+	>=x11-libs/gtk+-2.90.0:3[introspection?]
+	x11-libs/libX11
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-build/gtk-doc-am-1.11
+	virtual/pkgconfig
+"
+# For eautoreconf
+#	dev-build/gtk-doc-am
+
+src_configure() {
+	# --disable-dbus means gdbus is used instead of dbus-glib
+	gnome2_src_configure \
+		--disable-maintainer-flags \
+		--disable-dbus \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable introspection)
+}
+
+src_test() {
+	cd "${S}/tests" || die
+	cp "${FILESDIR}/run-tests" . || die "Unable to cp \${FILESDIR}/run-tests"
+	virtx emake -f run-tests
+}