[gentoo-commits] repo/gentoo:master commit in: dev-libs/ncnn/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     8cab2daba82cb936141a4a5573d09a61237919a8
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 10 18:45:13 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Wed Apr 10 18:50:09 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8cab2dab

dev-libs/ncnn: add 20240410

As usual the build system files changes are very noisy making it
hard to tell what needs attention and ebuild updates. Please report
if there is something that needs to be done that I didn't see.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 dev-libs/ncnn/Manifest             |  1 +
 dev-libs/ncnn/ncnn-20240410.ebuild | 64 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-libs/ncnn/Manifest b/dev-libs/ncnn/Manifest
index 592ae5fadcbd..2792cf0ec9c4 100644
--- a/dev-libs/ncnn/Manifest
+++ b/dev-libs/ncnn/Manifest
@@ -1 +1,2 @@
 DIST ncnn-20240102.tar.gz 12791570 BLAKE2B 8a84353343d32bea1ef163a83cdef783a8a6077282e94a012d21a17b2e0d8c78c576ebd1dc5c9ec89364942b4ce69ab44d544648fe2dbd5fda4797b3b65adfd8 SHA512 31bc3c2f461a00241fb8f69ca6ea8cc590af6618856b1b84a048bde924e4b474fd883ad5d54dbfbdd1e5b59015889e15ffc4fbafccb3e42e052a02071f2017b1
+DIST ncnn-20240410.tar.gz 12835689 BLAKE2B b4c2ffdf525719dca81d020695f03cd963c3a1f1a0ecc61b6e08c75da212d280210bf1be9b54343a771661fef747675e7f08d0dd9e3ea942adfda1e07d1f6868 SHA512 61865af26aecc6b0eccdfd46c5b3f6e4dd06d7409298051c91d141e64b8c15690f2f982c0aeb3a11d3a575061ab7606710cb0e710f4cb6539c7a14ff440aaaf7

diff --git a/dev-libs/ncnn/ncnn-20240410.ebuild b/dev-libs/ncnn/ncnn-20240410.ebuild
new file mode 100644
index 000000000000..9e49183c454a
--- /dev/null
+++ b/dev-libs/ncnn/ncnn-20240410.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="High-performance neural network inference framework"
+HOMEPAGE="https://github.com/Tencent/ncnn/"
+SRC_URI="
+	https://github.com/Tencent/ncnn/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="BSD ZLIB"
+SLOT="0/${PV}" # currently has unstable ABI that often requires rebuilds
+KEYWORDS="~amd64 ~x86"
+IUSE="openmp tools +vulkan"
+
+# Need the static library to run tests + skip vulkan / GPU:
+# -DNCNN_BUILD_TESTS=ON -DNCNN_SHARED_LIB=OFF -DNCNN_VULKAN=OFF
+RESTRICT="test"
+
+RDEPEND="
+	tools? (
+		dev-cpp/abseil-cpp:=
+		dev-libs/protobuf:=
+	)
+	vulkan? (
+		dev-util/glslang:=
+		media-libs/vulkan-loader
+	)
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+
+DOCS=( README.md docs/. )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DGLSLANG_TARGET_DIR="${ESYSROOT}"/usr/$(get_libdir)/cmake
+		-DNCNN_BUILD_EXAMPLES=no
+		-DNCNN_BUILD_TOOLS=$(usex tools)
+		-DNCNN_OPENMP=$(usex openmp)
+		-DNCNN_PYTHON=no # todo if something needs it
+		-DNCNN_SHARED_LIB=yes
+		-DNCNN_SIMPLEVK=no
+		-DNCNN_SYSTEM_GLSLANG=yes
+		-DNCNN_VERSION=${PV} # avoids libncnn.so.*.%Y%m%d using build date
+		-DNCNN_VULKAN=$(usex vulkan)
+	)
+
+	cmake_src_configure
+}