[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd-efi/

["Marek Szuba" <marecki@gentoo.org>]

commit:     cceec97ea9b51b69a57cbc8229e10b16c00149b0
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  7 15:43:10 2024 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sun Apr  7 18:26:20 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cceec97e

sys-apps/fwupd-efi: add 1.5

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 sys-apps/fwupd-efi/Manifest             |  1 +
 sys-apps/fwupd-efi/fwupd-efi-1.5.ebuild | 62 +++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/sys-apps/fwupd-efi/Manifest b/sys-apps/fwupd-efi/Manifest
index 3fad41df7a08..cbec4718721f 100644
--- a/sys-apps/fwupd-efi/Manifest
+++ b/sys-apps/fwupd-efi/Manifest
@@ -1 +1,2 @@
 DIST fwupd-efi-1.4.tar.xz 35984 BLAKE2B 24ce9788500781aac5b856740dc17d94bec79cf57f4f1a0359f42e6be4b9600d34259794a88f69bf83aa38ee5976b26228b20813f717edce5cc627c163585b40 SHA512 c330409861a8c1e332a0d4fd49c54ef2c5bf7cdaca99d14de39b50fb35f0c490e9f7f7a4c9dd48181bd509cd358c43eb23659536aea93408c1fefb47629e4991
+DIST fwupd-efi-1.5.tar.xz 38460 BLAKE2B fe2d06e9d9a588b524a6a26afc401898f8dd1d3bd49fa608cfaa6c32ec71a88f125d2158e3892a44706cc2f8349ed379ee8d7b62bfbe8ba38990d1545eff9f94 SHA512 b1edaa1fa4b7e768ee822c92bdd2858343993f19edde6445e333fad470f997420aeab10dd36e5abff90cb0a87d8f3b2a0de9e7cf49a03758e0e1c9c2fd06ef19

diff --git a/sys-apps/fwupd-efi/fwupd-efi-1.5.ebuild b/sys-apps/fwupd-efi/fwupd-efi-1.5.ebuild
new file mode 100644
index 000000000000..a136dde4ec54
--- /dev/null
+++ b/sys-apps/fwupd-efi/fwupd-efi-1.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-any-r1 secureboot
+
+DESCRIPTION="EFI executable for fwupd"
+HOMEPAGE="https://fwupd.org"
+
+if [[ ${PV} = *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fwupd/fwupd-efi.git"
+else
+	SRC_URI="https://github.com/fwupd/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+BDEPEND="$(python_gen_any_dep '
+		dev-python/pefile[${PYTHON_USEDEP}]
+	')
+	virtual/pkgconfig"
+
+DEPEND="sys-boot/gnu-efi"
+
+python_check_deps() {
+	python_has_version "dev-python/pefile[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	secureboot_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	python_fix_shebang "${S}/efi"
+}
+
+src_configure() {
+	local emesonargs=(
+		-Defi-libdir="${EPREFIX}"/usr/$(get_libdir)
+		-Defi_sbat_distro_id="gentoo"
+		-Defi_sbat_distro_summary="Gentoo GNU/Linux"
+		-Defi_sbat_distro_pkgname="${PN}"
+		-Defi_sbat_distro_version="${PVR}"
+		-Defi_sbat_distro_url="https://packages.gentoo.org/packages/${CATEGORY}/${PN}"
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	secureboot_auto_sign
+}