[gentoo-commits] repo/gentoo:master commit in: dev-libs/libjcat/

["Marek Szuba" <marecki@gentoo.org>]

commit:     230f5ac5cdddbf02d4fe40a0ee71e5c767710df1
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  7 00:37:47 2024 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sun Apr  7 01:04:01 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=230f5ac5

dev-libs/libjcat: add 0.2.1

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 dev-libs/libjcat/Manifest             |  1 +
 dev-libs/libjcat/libjcat-0.2.1.ebuild | 82 +++++++++++++++++++++++++++++++++++
 dev-libs/libjcat/metadata.xml         |  2 +
 3 files changed, 85 insertions(+)

diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index bec0d8663d85..6331f7ea2ef2 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1 +1,2 @@
 DIST libjcat-0.1.14.tar.gz 70018 BLAKE2B 71329e6fc04ef37e5af215c88b4a5a03fbd65143604da57b0357d4bd07896a22a98b9028d8529234655adb37e5cefe226d09d987e798bce17b47fef1e1142d1f SHA512 837a50ad31a736a36bd9df26b151c198e18873df0e7444502b7a6e26a86df15f1df970112f2dd22658960389fdfb78a2c601274e2b5c46ec82fceef5aad778c1
+DIST libjcat-0.2.1.tar.gz 76698 BLAKE2B 62f77c993e47843dddacc9a67b9daac9bd29bef7363ce62125ecd22f9649b8a5ce2de07d74ea6900e9a45feb141caa19761bcffd337530d86a31b6ed94cab164 SHA512 e29fdaae38ade2960ffa7ac3cd41224ccab5fdb351d2ae420ffe0cf0ddb948bba37e9e040cc3046c8593be4622bf018779dfa80f173873b79582061f12c02373

diff --git a/dev-libs/libjcat/libjcat-0.2.1.ebuild b/dev-libs/libjcat/libjcat-0.2.1.ebuild
new file mode 100644
index 000000000000..80d7f848471c
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.2.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files"
+HOMEPAGE="https://github.com/hughsie/libjcat"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+ed25519 +gpg gtk-doc +introspection +man +pkcs7 test vala"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib:=
+	ed25519? (
+		dev-libs/nettle:=
+		net-libs/gnutls:=
+	)
+	gpg? (
+		app-crypt/gpgme:=
+		dev-libs/libgpg-error
+	)
+	introspection? ( dev-libs/gobject-introspection:= )
+	pkcs7? ( net-libs/gnutls:= )
+	vala? ( dev-lang/vala:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	')
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( sys-apps/help2man )
+	test? ( net-libs/gnutls[tools] )"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use vala && vala_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use ed25519)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use gpg)
+		$(meson_use introspection)
+		$(meson_use man)
+		$(meson_use pkcs7)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -rf \
+			"${ED}"/usr/libexec/installed-tests \
+			"${ED}"/usr/share/installed-tests \
+			|| die
+	fi
+}

diff --git a/dev-libs/libjcat/metadata.xml b/dev-libs/libjcat/metadata.xml
index aa3846c8eacb..01872545896e 100644
--- a/dev-libs/libjcat/metadata.xml
+++ b/dev-libs/libjcat/metadata.xml
@@ -13,6 +13,8 @@
 		in Microsoft Windows.
 	</longdescription>
 	<use>
+		<flag name="ed25519">Enable ED25519 verification support
+			via <pkg>dev-libs/nettle</pkg> and <pkg>net-libs/gnutls</pkg></flag>
 		<flag name="gpg">Enable GPG verification support via <pkg>app-crypt/gpgme</pkg></flag>
 		<flag name="pkcs7">Enable PKCS7 verification support via <pkg>net-libs/gnutls</pkg></flag>
 	</use>