[gentoo-commits] repo/gentoo:master commit in: dev-python/dask/

["Michał Górny" <mgorny@gentoo.org>]

commit:     f533eda6b4d3a368ca90088df498ba59aaabe55d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  5 18:56:27 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Apr  5 19:45:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f533eda6

dev-python/dask: Bump to 2024.4.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dask/Manifest             |  1 +
 dev-python/dask/dask-2024.4.1.ebuild | 99 ++++++++++++++++++++++++++++++++++++
 2 files changed, 100 insertions(+)

diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index 184e7d3474fe..87e70c4347b1 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -3,3 +3,4 @@ DIST dask-2024.2.1.gh.tar.gz 9341330 BLAKE2B f5d02fd7389711c5d7b048e541c28af87a8
 DIST dask-2024.3.0.gh.tar.gz 9342813 BLAKE2B d71d3ed2531517a1d01ab72862484b86a1080ecff056c11041ab723e67369794ca3c1f486cd18019f38e49deda65f25acb566e4431c6a1121ddfb930669b20b1 SHA512 be56244c7a96cf43062e7e3658befb73bf318729a2bb906d78ee8ba91a1f4fcfab22e6b01c00cda9bfb8de3f74adf8fc1a5dfb6681e51deb00ba5011dd1dc325
 DIST dask-2024.3.1.gh.tar.gz 9342821 BLAKE2B 2d85be59caa48005b1951d56c4af5991bc378932cac34fc9fcfdd4a55027cacf60738af11eab87d13f764b90d7cba74ba239e10949a8231d0e08d4e5a2eaf936 SHA512 465a489cdfd59eb7b20a4736549a0cee9bedb5b864339b1040c5490c70a4a7486a83bdf4d951a1ea15529685838dcdc4d2554b03ebd9b8227cce0d270e80a7cd
 DIST dask-2024.4.0.gh.tar.gz 9344730 BLAKE2B ef2da6ea07fae6b31ba0b02489aee64758348f4efff4d7a669a79464d878c6e2ca689ebcd4eacac479a12b81f68158b44a697d02ffe7d25f71121d38dc1e0753 SHA512 35ffd5f36eaa630730e64f3af6b256cb5225f665aaa7b89381e160f2dcb6f84c3b968a4c72fd2def687ac8432963555c0cd85e4a654a80b4576f1c677b0bd9bf
+DIST dask-2024.4.1.gh.tar.gz 9345547 BLAKE2B 5ac11e23e10985eb9641734d016b84600a67b4d30dfe999f1c7b6c4bb279ba622adf58262721b4c37701a265c02e22d989e94031a1d0b53435d1ecef054704d5 SHA512 683f548da4f0004181b912c1672d6bbefc33f7ab4f3fecee6634c13691ea718560cbaed6391e2380ae776ee1db850fc90bcc8feeea34dc85dd87332cff484726

diff --git a/dev-python/dask/dask-2024.4.1.ebuild b/dev-python/dask/dask-2024.4.1.ebuild
new file mode 100644
index 000000000000..1d1841fc6902
--- /dev/null
+++ b/dev-python/dask/dask-2024.4.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="
+	https://www.dask.org/
+	https://github.com/dask/dask/
+	https://pypi.org/project/dask/
+"
+SRC_URI="
+	https://github.com/dask/dask/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/click-8.1[${PYTHON_USEDEP}]
+	>=dev-python/cloudpickle-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-2021.9.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-1.2.0[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.10.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-4.13.0[${PYTHON_USEDEP}]
+	' 3.{10..11})
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	>=dev-python/versioneer-0.28[${PYTHON_USEDEP}]
+	test? (
+		dev-libs/apache-arrow[parquet,snappy]
+		dev-python/dask-expr[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pyarrow[parquet,${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# fails with sqlalchemy-2.0, even though we don't use it x_x
+	sed -i -e '/RemovedIn20Warning/d' pyproject.toml || die
+	sed -i -e 's:--cov-config=pyproject.toml::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# more tests relying on -Werror
+		"dask/array/tests/test_overlap.py::test_map_overlap_no_depth[None]"
+		dask/array/tests/test_random.py::test_RandomState_only_funcs
+		dask/dataframe/tests/test_dataframe.py::test_view
+		dask/dataframe/tests/test_shuffle.py::test_npartitions_auto_raises_deprecation_warning
+		# TODO
+		dask/array/tests/test_reductions.py::test_mean_func_does_not_warn
+		dask/tests/test_config.py::test__get_paths
+		dask/array/tests/test_linalg.py::test_solve_assume_a
+		"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>0-float-5-1-True]"
+		"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>1-float-5-1-True]"
+		dask/array/tests/test_image.py::test_preprocess
+		dask/tests/test_system.py::test_cpu_count_cgroups_v2
+		dask/dataframe/tests/test_dataframe.py::test_attribute_assignment
+		# require sqlalchemy<2.0
+		dask/dataframe/io/tests/test_sql.py
+		# crashes
+		dask/tests/test_base.py::test_tokenize_object_with_recursion_error
+		# regression with new pandas (?)
+		dask/dataframe/tests/test_multi.py::test_concat5
+	)
+
+	if ! has_version -b "dev-python/pyarrow[parquet,${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# fails if pyarrow is installed without USE=parquet
+			# (optional dep, skipped if it's not installed at all)
+			dask/dataframe/io/tests/test_parquet.py::test_pyarrow_filter_divisions
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_rerunfailures -m "not network" -o xfail_strict=False
+}