[gentoo-commits] repo/proj/guru:dev commit in: dev-java/corretto-bin/

["Robert Greener" <me@r0bert.dev>]

commit:     7b290faa3669cd7a05c2e43fb5b06e3ef7477269
Author:     Robert Greener <me <AT> r0bert <DOT> dev>
AuthorDate: Wed Apr  3 18:42:41 2024 +0000
Commit:     Robert Greener <me <AT> r0bert <DOT> dev>
CommitDate: Wed Apr  3 18:43:48 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=7b290faa

dev-java/corretto-bin: New revision 8.402.08.1-r1

Remove faulty use flags

Bug: https://bugs.gentoo.org/928434

Signed-off-by: Robert Greener <me <AT> r0bert.dev>

 .../corretto-bin/corretto-bin-8.402.08.1-r1.ebuild | 78 ++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/dev-java/corretto-bin/corretto-bin-8.402.08.1-r1.ebuild b/dev-java/corretto-bin/corretto-bin-8.402.08.1-r1.ebuild
new file mode 100644
index 0000000000..ff357b12e6
--- /dev/null
+++ b/dev-java/corretto-bin/corretto-bin-8.402.08.1-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2 toolchain-funcs
+
+MY_PV=${PV/_p/+}
+SLOT=$(ver_cut 1)
+
+SRC_URI="
+    https://corretto.aws/downloads/resources/${PV}/amazon-corretto-${PV}-linux-x64.tar.gz
+"
+
+DESCRIPTION="Prebuilt Java JDK binaries provided by Amazon Web Services"
+HOMEPAGE="https://aws.amazon.com/corretto"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="cups headless-awt selinux source"
+
+RDEPEND="
+	>=sys-apps/baselayout-java-0.1.0-r1
+	kernel_linux? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+		media-libs/harfbuzz
+		elibc_glibc? ( >=sys-libs/glibc-2.2.5:* )
+		elibc_musl? ( sys-libs/musl )
+		sys-libs/zlib
+		cups? ( net-print/cups )
+		selinux? ( sec-policy/selinux-java )
+		!headless-awt? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			x11-libs/libXtst
+		)
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/amazon-corretto-${MY_PV}-linux-x64"
+
+pkg_pretend() {
+	if [[ "$(tc-is-softfloat)" != "no" ]]; then
+		die "These binaries require a hardfloat system."
+	fi
+}
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}/${dest#/}"
+
+	if use headless-awt ; then
+		rm -v lib/amd64/libjawt.so || die
+	fi
+
+	if ! use source ; then
+		rm -v src.zip || die
+	fi
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	java-vm_install-env "${FILESDIR}"/${PN}-8.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+}
\ No newline at end of file