[gentoo-commits] repo/gentoo:master commit in: media-libs/libva/

["Matt Turner" <mattst88@gentoo.org>]

commit:     eb0257b1eae46f10c3e67cede7c1d90c8ecb7a08
Author:     Konstantin Fedotov <zenflak <AT> gmail <DOT> com>
AuthorDate: Fri Mar 15 23:29:04 2024 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Mar 27 15:55:05 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb0257b1

media-libs/libva: add 2.21.0

Signed-off-by: Konstantin Fedotov <zenflak <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35776
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-libs/libva/Manifest            |  1 +
 media-libs/libva/libva-2.21.0.ebuild | 67 ++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-libs/libva/Manifest b/media-libs/libva/Manifest
index 13feecbbf8ea..9e846cbb2b19 100644
--- a/media-libs/libva/Manifest
+++ b/media-libs/libva/Manifest
@@ -1 +1,2 @@
 DIST libva-2.20.0.tar.gz 280079 BLAKE2B bb1b7f8757d068765fa69e57e8747e0bbd61ea0874bd42d27e0a99786cad2a4a81d7c20a28ff977cebcef54cd8cafa6c0493c18b563ad1ab47a9c3190d0cd1c6 SHA512 85f4aa6b6e9173d407ca3987745f985d0f898091f14c947a928b6db662a03b5cfe82483901690d81618697fe17a2c41ff6694a611f3654d5ab06840da987e40d
+DIST libva-2.21.0.tar.gz 281515 BLAKE2B bd430162b07987d8982d8f81296e94623efea68624f34b7e159ebefeb37a2b062f2c0d809e16e76c172d6c2df11b59691174fb9a1d65d0938949ac2a025b746c SHA512 93654bb892e0e269d7682a1344fe6f7298432d1f2b347396c63aa1bd84ac0f707af34950a93098fe86a9bc8986fc9f97f75f0f15d8495ffd2caf8cf0eed9612c

diff --git a/media-libs/libva/libva-2.21.0.ebuild b/media-libs/libva/libva-2.21.0.ebuild
new file mode 100644
index 000000000000..009f40c00c1c
--- /dev/null
+++ b/media-libs/libva/libva-2.21.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib optfeature
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+else
+	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~mips ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="wayland X"
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.60[${MULTILIB_USEDEP}]
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+		x11-libs/libxcb:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	wayland? ( dev-util/wayland-scanner )
+	virtual/pkgconfig
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/va/va_x11.h
+	/usr/include/va/va_dri2.h
+	/usr/include/va/va_dricommon.h
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddriverdir="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		-Ddisable_drm=false
+		-Dwith_x11=$(usex X)
+		-Dwith_glx=no
+		-Dwith_wayland=$(usex wayland)
+		-Denable_docs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature_header
+	optfeature "Older Intel GPU support up to Gen8" media-libs/libva-intel-driver
+	optfeature "Newer Intel GPU support from Gen9+" media-libs/libva-intel-media-driver
+}