[gentoo-commits] repo/gentoo:master commit in: dev-util/meld/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     fb8a03fdb6c8f533d081ebdf455d26f02ca270f6
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 24 20:10:57 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 24 20:45:01 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb8a03fd

dev-util/meld: add 3.22.2

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-util/meld/Manifest           |  1 +
 dev-util/meld/meld-3.22.2.ebuild | 74 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-util/meld/Manifest b/dev-util/meld/Manifest
index be81f8fa181c..3087c33ec47a 100644
--- a/dev-util/meld/Manifest
+++ b/dev-util/meld/Manifest
@@ -1,2 +1,3 @@
 DIST meld-3.22.0.tar.xz 674212 BLAKE2B 1d5af5fa9943c46fd150bd1e1c74003579a0017dea56178e92c4ba0dd1ba0bc3348a6f2625bfe5191fe4d8394b06462a30f2173ae623ffd32c637642f9c36183 SHA512 4cc1c9a76379401c1f116292bb4730301ec0f2413cdab7b463ed519ea7ee0ee86143a9c83a13f1ef09860aad192c04769d111bfb1eb10b5e1bc81fb44c530526
 DIST meld-3.22.1.tar.xz 675984 BLAKE2B 47ad8cc0b3f55e2ab8066bd811a925eb12446d041b26220d56a11eedc727042357c8bbec26a5b9f1a9e220357753968acbc43dd257fe48013a3fcf7ef4243364 SHA512 7cb4c64a8134d02ee629c5459d5361c8ee1b1fb80efb02b9f3d2c577ecb69dca2ff66b90affb479682b7fceda41c60717ef859d93e3b93070a84901ae772b2cd
+DIST meld-3.22.2.tar.xz 676376 BLAKE2B 5e592e378ac2c942dd98df6d9ac4f9af7a1eee552af1691aade2e0f453a5ddf649ca09c38191b2c2ffdb7b6fa165012b4d8372e9e99c33052f612e2ab8ca8670 SHA512 fd8b12567cd8dcf77f265d831c9ac9ba33d13fb78c95b01b496b016308ff4159963b4610a68f41d04a52cc5bcc13bb4568d24bbade5bd79246111e463e413284

diff --git a/dev-util/meld/meld-3.22.2.ebuild b/dev-util/meld/meld-3.22.2.ebuild
new file mode 100644
index 000000000000..48ffb7c894f2
--- /dev/null
+++ b/dev-util/meld/meld-3.22.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="A graphical diff and merge tool"
+HOMEPAGE="http://meldmerge.org/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.20:3[introspection]
+	>=dev-libs/glib-2.48:2
+	>=x11-libs/gtksourceview-4.0.0:4[introspection]
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.30:3[cairo,${PYTHON_USEDEP}]
+	')
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/pango-1.34[introspection]
+	x11-themes/hicolor-icon-theme
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-util/desktop-file-utils
+		dev-libs/appstream-glib
+	)
+"
+BDEPEND="
+	dev-util/intltool
+	dev-util/itstool
+	sys-devel/gettext
+	$(python_gen_cond_dep 'dev-python/distro[${PYTHON_USEDEP}]')
+"
+# dev-python/distro is soft-required in BDEPEND for python3.8 and onwards,
+# but it's mainly needed for debian and derivatives - seems the fallback
+# works fine, as we aren't a special_case, just an annoying warning.
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=''
+		-Dbyte-compile=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	python_fix_shebang "${ED}"/usr/bin/meld
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}