[gentoo-commits] repo/gentoo:master commit in: dev-python/hatchling/

["Michał Górny" <mgorny@gentoo.org>]

commit:     9c25c688652282dc1a4ee3126ca6be204c15a653
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 24 02:45:42 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Mar 24 02:45:42 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9c25c688

dev-python/hatchling: Bump to 1.22.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/hatchling/Manifest                |  1 +
 dev-python/hatchling/hatchling-1.22.4.ebuild | 87 ++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index ff2a3bb97458..00743521d011 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,3 +1,4 @@
 DIST hatch-hatchling-v1.21.1.gh.tar.gz 774577 BLAKE2B 31e2b50598b4fe120ecea407a37e3262876a2ec1e8cf02f272c25838e73afc37f2fef1f8fab08b2e3b83bfd828f6c558ce303b084081b83504343a8bb057c341 SHA512 91b5684737fac19758d7095b357f99031d46e9f981e093cab848ce770fd1f9440b69212f3ef2217e3700e7dd7985a97c2735bbd27b306c7b8aa7bffc5c950fb4
 DIST hatch-hatchling-v1.22.2.gh.tar.gz 782675 BLAKE2B 1b8dd52627cbbc87c8ed2d4b8f41f339fd59ee5e641f8d14f88c200b085d0d783397b406d4c2e0fc38a4c0545d02e03c8c3c4f19ab810828b522571e807b9460 SHA512 fe5fa174f07b552d46fb75d092b6e992cff8f0a72b994336b8593b807fdf61cc07ab5a90097099a7f30d3da34b4ce9a3d9313316cfd97f3b0e731bd2d7d3511e
 DIST hatch-hatchling-v1.22.3.gh.tar.gz 782744 BLAKE2B aa60f8ecf7ab28b04cba8586085326b267a54210dba41d93c5b8e0cbb5f4a4a8cbe33387d08b975d00c8799b29336513d51825cdfed6c4765142148be72833e8 SHA512 059667e0ed2ad1c1d305800a88a8e218daa6cf11bdf0507ebe8630fbea1ef412159f779853213d1dc3121b5434474f5b319da4168cd72a3c6d983a7d384f0c2e
+DIST hatch-hatchling-v1.22.4.gh.tar.gz 782805 BLAKE2B 06cf7b07cdb35223c6ffb9403a26b50ec93decb19e58199dc17ae4d924bfaf20625270d4721bc27adfcdd3a345b80409fe9487bb457644077f6a4b7d2ee082c0 SHA512 e33dec3494cd760fdf07de532367fccc63a91a67e408fe5c7ac60bf568093ea0419f6e9d5bfd49aa9c9415d79f006c4b3794b96e91aa97af4e7b87b129c4b448

diff --git a/dev-python/hatchling/hatchling-1.22.4.ebuild b/dev-python/hatchling/hatchling-1.22.4.ebuild
new file mode 100644
index 000000000000..880c81d559bb
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.22.4.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..12} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+# editables are optional but required for editable installs
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/trove-classifiers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+		# broken if CARGO is set
+		tests/backend/builders/test_binary.py::TestBuildBootstrap::test_no_cargo
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	# sigh; standalone test suites are overrated, right?
+	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
+	# tests mock cargo subprocess call but the backend raises if CARGO
+	# is not set and shutil.which() can't find it
+	local -x CARGO=cargo
+	epytest tests/backend
+}