[gentoo-commits] repo/gentoo:master commit in: net-dialup/wvdial/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     3e4fe8d2cfff021bc8ab557985bf67ff61866965
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Sun Mar 17 18:49:03 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon Mar 18 20:00:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e4fe8d2

net-dialup/wvdial: EAPI8 bump

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/35804
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 net-dialup/wvdial/wvdial-1.61-r1.ebuild | 46 +++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/net-dialup/wvdial/wvdial-1.61-r1.ebuild b/net-dialup/wvdial/wvdial-1.61-r1.ebuild
new file mode 100644
index 000000000000..1184b267e853
--- /dev/null
+++ b/net-dialup/wvdial/wvdial-1.61-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit readme.gentoo-r1
+
+DESCRIPTION="Excellent program to automatically configure PPP sessions"
+HOMEPAGE="https://code.google.com/archive/p/wvstreams/"
+SRC_URI="https://wvstreams.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
+
+DEPEND=">=net-libs/wvstreams-4.4"
+RDEPEND="${DEPEND}
+	net-dialup/ppp:=
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-destdir.patch"
+	"${FILESDIR}/${P}-as-needed.patch"
+	"${FILESDIR}/${P}-parallel-make.patch"
+)
+
+DOC_CONTENTS="
+	Use wvdialconf to automagically generate a configuration file.
+	Users have to be member of the dialout AND the uucp group to use
+	wvdial
+"
+
+src_configure() {
+	# Hand made configure...
+	./configure || die
+}
+
+src_install() {
+	default
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}