[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-control-center/files/, gnome-extra/cinnamon-control-center/

["Sam James" <sam@gentoo.org>]

commit:     20a9ce835b76599fa97c3ae8e743b7ac7ff96890
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 17 03:15:37 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Mar 17 03:15:37 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=20a9ce83

gnome-extra/cinnamon-control-center: fix modern C issue

Closes: https://bugs.gentoo.org/919085
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../cinnamon-control-center-6.0.0-r1.ebuild        | 123 +++++++++++++++++++++
 .../files/cinnamon-control-center-6.0.0-c99.patch  |  21 ++++
 2 files changed, 144 insertions(+)

diff --git a/gnome-extra/cinnamon-control-center/cinnamon-control-center-6.0.0-r1.ebuild b/gnome-extra/cinnamon-control-center/cinnamon-control-center-6.0.0-r1.ebuild
new file mode 100644
index 000000000000..542e240d4060
--- /dev/null
+++ b/gnome-extra/cinnamon-control-center/cinnamon-control-center-6.0.0-r1.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson gnome2-utils python-any-r1 xdg virtualx
+
+DESCRIPTION="Cinnamons's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-control-center"
+SRC_URI="https://github.com/linuxmint/cinnamon-control-center/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="+colord input_devices_wacom +networkmanager +modemmanager gnome-online-accounts systemd test wayland"
+REQUIRED_USE="modemmanager? ( networkmanager )"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	app-accessibility/at-spi2-core:2
+	>=dev-libs/glib-2.44.0:2
+	>=gnome-base/libgnomekbd-3.0.0:0=
+	>=gnome-extra/cinnamon-desktop-6.0:0=
+	>=gnome-extra/cinnamon-menus-6.0
+	media-libs/fontconfig
+	>=sys-auth/polkit-0.103
+	>=sys-power/upower-0.99.8:=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.16.0:3[wayland=]
+	>=dev-libs/libgudev-232
+	>=x11-libs/libnotify-0.7.3
+	x11-libs/cairo
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5.1:=
+	x11-libs/pango
+
+	colord? (
+		>=x11-misc/colord-0.1.14:0=
+	)
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7:=
+		>=x11-libs/libXi-1.2
+	)
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-libs/libnma-1.8.34
+		>=net-misc/networkmanager-1.2.0[modemmanager?]
+
+		modemmanager? (
+			>=net-misc/modemmanager-0.7:=
+		)
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.18.0:=
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+
+	colord? (
+		>=gnome-extra/gnome-color-manager-3
+	)
+	input_devices_wacom? (
+		gnome-extra/cinnamon-settings-daemon[input_devices_wacom]
+	)
+	systemd? (
+		>=sys-apps/systemd-31
+	)
+	!systemd? (
+		app-admin/openrc-settingsd
+	)
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-text/iso-codes
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Fix optional wayland
+	# https://github.com/linuxmint/cinnamon-control-center/pull/323
+	"${FILESDIR}/${PN}-6.0.0-fix-optional-wayland.patch"
+	"${FILESDIR}/${PN}-6.0.0-c99.patch"
+)
+
+src_prepare() {
+	default
+	python_fix_shebang meson_install_schemas.py
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord color)
+		$(meson_use modemmanager)
+		$(meson_use networkmanager)
+		$(meson_use gnome-online-accounts onlineaccounts)
+		$(meson_use input_devices_wacom wacom)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}

diff --git a/gnome-extra/cinnamon-control-center/files/cinnamon-control-center-6.0.0-c99.patch b/gnome-extra/cinnamon-control-center/files/cinnamon-control-center-6.0.0-c99.patch
new file mode 100644
index 000000000000..b5a73ae3186d
--- /dev/null
+++ b/gnome-extra/cinnamon-control-center/files/cinnamon-control-center-6.0.0-c99.patch
@@ -0,0 +1,21 @@
+https://bugs.gentoo.org/919085
+https://github.com/linuxmint/cinnamon-control-center/commit/0361ff2974eb4741f3cd8b6db00dbe1ab56c8a59
+
+From 0361ff2974eb4741f3cd8b6db00dbe1ab56c8a59 Mon Sep 17 00:00:00 2001
+From: Leigh Scott <leigh123linux@gmail.com>
+Date: Thu, 18 Jan 2024 21:30:28 +0000
+Subject: [PATCH] network: Fix warning about missing cast to GtkWidget* (#324)
+
+Based on https://github.com/GNOME/gnome-control-center/commit/167d11e2107e46b4621cf6fc370c5b191b4b7732
+--- a/panels/network/connection-editor/net-connection-editor.c
++++ b/panels/network/connection-editor/net-connection-editor.c
+@@ -845,7 +845,7 @@ net_connection_editor_new (GtkWindow        *parent_window,
+         editor = g_object_new (NET_TYPE_CONNECTION_EDITOR, NULL);
+ 
+         if (parent_window) {
+-                editor->parent_window = g_object_ref (parent_window);
++                editor->parent_window = GTK_WIDGET (g_object_ref (parent_window));
+                 gtk_window_set_transient_for (GTK_WINDOW (editor->window),
+                                               parent_window);
+         }
+