[gentoo-commits] repo/gentoo:master commit in: x11-misc/safeeyes/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     07a8db8179d87bfb26d091aa2b329d58c31993db
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 14 20:54:48 2024 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Thu Mar 14 21:11:53 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07a8db81

x11-misc/safeeyes: Move assets and .desktop file in place

Closes: https://bugs.gentoo.org/926816
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>

 x11-misc/safeeyes/safeeyes-2.1.6-r3.ebuild | 64 ++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/x11-misc/safeeyes/safeeyes-2.1.6-r3.ebuild b/x11-misc/safeeyes/safeeyes-2.1.6-r3.ebuild
new file mode 100644
index 000000000000..7f1927eab085
--- /dev/null
+++ b/x11-misc/safeeyes/safeeyes-2.1.6-r3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_REQ_USE="tk"  # for site-packages/Xlib/ext/randr.py
+DISTUTILS_USE_PEP517=setuptools
+
+inherit xdg distutils-r1 pypi
+
+DESCRIPTION="Linux alternative to EyeLeo"
+HOMEPAGE="https://github.com/slgobinath/SafeEyes"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-py312.patch
+)
+
+RDEPEND="
+	dev-libs/libayatana-appindicator
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/croniter[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/python-xlib[${PYTHON_USEDEP}]
+	media-sound/alsa-utils
+	x11-apps/xprop
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	x11-misc/xprintidle
+	"
+
+python_install() {
+	distutils-r1_python_install
+
+	# Workaround for https://bugs.gentoo.org/926816
+	# Files were misplaced and also duplicate across Python slots.
+	local misplaced_usr="${D}/usr/lib/${EPYTHON}/site-packages/usr"
+	local i
+	for i in applications icons ; do
+		local source="${misplaced_usr}/share/${i}"
+		local target="${D}/usr/share/${i}"
+		if [[ ! -d "${target}" ]]; then
+			dodir /usr/share/
+			mv "${source}" "${target}" || die
+		fi
+	done
+	rm -R "${misplaced_usr}" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}