[gentoo-commits] repo/gentoo:master commit in: net-libs/gnome-online-accounts/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     be16af8fd8a167f092d9892ff79da6cb3367622c
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 14 12:01:33 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Thu Mar 14 12:01:33 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=be16af8f

net-libs/gnome-online-accounts: add 3.48.1

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 net-libs/gnome-online-accounts/Manifest            |  1 +
 .../gnome-online-accounts-3.48.1.ebuild            | 78 ++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 35274bb65ceb..270e848e0346 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1 +1,2 @@
 DIST gnome-online-accounts-3.48.0.tar.xz 382964 BLAKE2B 9b64329415118ca3d44f4662db31d82f262c27b4d8cda8ba9eb05b8e606081ae3eb06b5bf691c165b9bb7cf984fdeba8389390d72a4b3595a7d39b1d6ea11df1 SHA512 67e6c39d38187dc58175f6b694c66a92d9b9152b179db41ee05a8c512db5b16f1dd1eb1503c7d732b09126942abc00206ba956f7a54c6ae7a285a9e3101be7a5
+DIST gnome-online-accounts-3.48.1.tar.xz 383124 BLAKE2B a9e18bf034454429a84be0920110f4d74fba9462fb1f7f23e74f304e963323413d99af2d84caa9ef1c6841917f5b8249ac94dc433ba04546f2ae23d6268dcd70 SHA512 8f191994b8f38bee4b922b10b94e96d6f7cb323de0e9a1f29febea848cb2002320357262ccf6f28839e32e9216faeb28a871f878e1ad9478c61650fdd3549737

diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.48.1.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.48.1.ebuild
new file mode 100644
index 000000000000..e6caacf8a6f7
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.48.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="debug gnome gtk-doc +introspection kerberos man +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.67.4:2
+	sys-apps/dbus
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	>=x11-libs/gtk+-3.19.12:3
+	>=net-libs/webkit-gtk-2.33.1:4.1
+	>=dev-libs/json-glib-0.16
+	>=app-crypt/libsecret-0.5
+	>=net-libs/libsoup-3.0:3.0
+	dev-libs/libxml2:2
+	>=net-libs/rest-0.9.0:1.0
+	kerberos? (
+		app-crypt/gcr:0=[gtk]
+		app-crypt/mit-krb5
+	)
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+BDEPEND="gtk-doc? ( dev-util/gtk-doc )"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	local emesonargs=(
+		-Dgoabackend=true
+		-Dinspector=false
+		-Dexchange=true
+		-Dfedora=false
+		-Dgoogle=true
+		-Dimap_smtp=true
+		$(meson_use kerberos)
+		-Dlastfm=true
+		-Dmedia_server=true
+		-Downcloud=true
+		-Dwindows_live=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dman=true
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}