[gentoo-commits] repo/gentoo:master commit in: dev-python/python-lsp-server/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1e0142cdb6d5edfef78be0dc5029ef9f26b6b1fb
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 13 06:13:50 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Mar 13 06:51:37 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e0142cd

dev-python/python-lsp-server: Bump to 1.10.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/python-lsp-server/Manifest              |   1 +
 .../python-lsp-server-1.10.1.ebuild                | 107 +++++++++++++++++++++
 2 files changed, 108 insertions(+)

diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index 8ebdcb9571ba..074dfdd8de91 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1 +1,2 @@
 DIST python-lsp-server-1.10.0.tar.gz 112917 BLAKE2B 2429e136ea2732d3bdfc2c77424a864364a7eb98bd447273d514fa53238b1ec276d46a51e558be8d959f100cd4dcfadf3a3eac996aa49b6b011babea84e8e3a8 SHA512 342452a5e3b1ae448a993f64501b2162b286f009026f1b5d306621c4befd0188699fc682206d50d06a93d8780862c8476186f8d0e4bb20592ddbbade1276445c
+DIST python-lsp-server-1.10.1.tar.gz 113136 BLAKE2B d1e39e3354d5ab67bb465265c6c3514f25ba4857fa3379e502d3c40b456f6d228c63ad759af1832b4d089fb93a03c7f3d6797cea4079b63cdc58e3591e9d783a SHA512 4c8e6a72ef6004248a5cb4a1e4c251b9d487cd4ce39d6c7268ce611c8537d6a5912eeb49d2eb1a25c230934b17e9a624504591c25f0291e07971eeccb70b09ba

diff --git a/dev-python/python-lsp-server/python-lsp-server-1.10.1.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.10.1.ebuild
new file mode 100644
index 000000000000..8f0c7de51fc0
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.10.1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-server/
+	https://pypi.org/project/python-lsp-server/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="all-plugins"
+
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.1.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-2.0.4[${PYTHON_USEDEP}]
+		>=dev-python/flake8-7[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/rope-1.11.0[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/pandas[${PYTHON_USEDEP}]
+			dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+			>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+# Note: xdist breaks some tests
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by presence of pathlib2
+		'test/plugins/test_autoimport.py'
+	)
+	local EPYTEST_IGNORE=(
+		# pydocstyle is archived upstream and broken with py3.12
+		test/plugins/test_pydocstyle_lint.py
+	)
+
+	if [[ ${EPYTHON} == pypy3 ]] ; then
+		# Not all plugins are available for pypy3
+		EPYTEST_IGNORE+=(
+			test/plugins/test_autoimport.py
+			test/plugins/test_completion.py
+			test/plugins/test_rope_rename.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}