[gentoo-commits] repo/gentoo:master commit in: media-sound/kid3/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     6b7670433a88937f040755620bcf3cbddcfea362
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 11 09:24:50 2024 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Mon Mar 11 09:24:50 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6b767043

media-sound/kid3: bump to 3.9.5

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/kid3/Manifest          |   1 +
 media-sound/kid3/kid3-3.9.5.ebuild | 101 +++++++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/media-sound/kid3/Manifest b/media-sound/kid3/Manifest
index 9c43b7e3e8e5..7a7d07321451 100644
--- a/media-sound/kid3/Manifest
+++ b/media-sound/kid3/Manifest
@@ -1 +1,2 @@
 DIST kid3-3.9.4.tar.xz 1834140 BLAKE2B 7a429b763bf4b0a275f9ba41dd0af314d564bcc8963093fefc10499e3e0e567d838515983b23cf9dfd5121adecce63b83d2179abca7904345d5b9f15a3c87aee SHA512 28fe76ab6101202445d419c1a8a1bc4dfe31c9924fb6d28203ff9c0d2926b20e3a10a5f8b10e9193ff889e93100ce8bc6663baa29cfdecd5ec9dfb3445489348
+DIST kid3-3.9.5.tar.xz 1843528 BLAKE2B 6bd7cf85eb6da91e1fb2dad40f63cdd443b1f75f3fab685f7af3caa5727f49afbf9b53a8d304f5e127743c4e0f8e3672b62fca33cf6de0a02ef091e758b2335a SHA512 a5b21ebabeddb49a2755fd1b5c563a822419d2a82184182bda85e5be9932ccd9626e969f944fb55cfa4c85f7c7c9821adba75375f966ee90272c2cf2283acdd8

diff --git a/media-sound/kid3/kid3-3.9.5.ebuild b/media-sound/kid3/kid3-3.9.5.ebuild
new file mode 100644
index 000000000000..5917cb2a450f
--- /dev/null
+++ b/media-sound/kid3/kid3-3.9.5.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake kde.org python-any-r1 xdg
+
+DESCRIPTION="Simple tag editor based on Qt"
+HOMEPAGE="https://kid3.kde.org/"
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+"
+SLOT="5"
+IUSE="acoustid flac kde mp3 mp4 +mpris +taglib test vorbis"
+
+REQUIRED_USE="flac? ( vorbis )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/readline:=
+	acoustid? (
+		media-libs/chromaprint:=
+		media-video/ffmpeg:=
+	)
+	flac? (
+		media-libs/flac:=[cxx]
+		media-libs/libvorbis
+	)
+	kde? (
+		kde-frameworks/kconfig:5
+		kde-frameworks/kconfigwidgets:5
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+		kde-frameworks/kwidgetsaddons:5
+		kde-frameworks/kxmlgui:5
+	)
+	mp3? ( media-libs/id3lib )
+	mp4? ( media-libs/libmp4v2 )
+	mpris? ( dev-qt/qtdbus:5 )
+	taglib? ( >=media-libs/taglib-1.9.1 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="${PYTHON_DEPS}
+	dev-qt/linguist-tools:5
+	kde? ( kde-frameworks/extra-cmake-modules:0 )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# overengineered upstream build system
+	cmake_src_prepare
+	# applies broken python hacks, bug #614950
+	cmake_comment_add_subdirectory doc
+
+	sed -e "/^ *find_package.*QT NAMES/s/Qt6 //" \
+		-i CMakeLists.txt || die # ensure Qt5 build
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=OFF
+		-DWITH_QAUDIODECODER=ON # bug 855281
+		-DWITH_CHROMAPRINT=$(usex acoustid)
+		-DWITH_DBUS=$(usex mpris)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_ID3LIB=$(usex mp3)
+		-DWITH_MP4V2=$(usex mp4)
+		-DWITH_TAGLIB=$(usex taglib)
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_VORBIS=$(usex vorbis)
+	)
+
+	if use kde ; then
+		mycmakeargs+=( "-DWITH_APPS=KDE;CLI" )
+	else
+		mycmakeargs+=( "-DWITH_APPS=Qt;CLI" )
+	fi
+
+	cmake_src_configure
+}