[gentoo-commits] repo/gentoo:master commit in: gui-libs/libpanel/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     0fe80f3202419d2d967156b60a5e1e7e2799c0a0
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  9 21:53:29 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Mar  9 22:45:12 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0fe80f32

gui-libs/libpanel: add 1.4.1

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gui-libs/libpanel/Manifest              |  1 +
 gui-libs/libpanel/libpanel-1.4.1.ebuild | 56 +++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/gui-libs/libpanel/Manifest b/gui-libs/libpanel/Manifest
index 74f142a9ce60..9f7030db34c1 100644
--- a/gui-libs/libpanel/Manifest
+++ b/gui-libs/libpanel/Manifest
@@ -1 +1,2 @@
 DIST libpanel-1.2.0.tar.xz 131296 BLAKE2B ee999166748e1cab227a970a9cc3ab05f47a88e5e9431b0e25f9e1933c31d13de1ce9a4132658905d6e0a7d7a6cc1ed214ff41d61ff3722355e7bc11465dce8a SHA512 28277d9679b71d6ea9ec891db2fad371e7f152240114def3ad84a24a4abe7b4de0dcec18448cd397dc79083109fdf2d0c9dd45bb198f059869a30b0f51afdb2f
+DIST libpanel-1.4.1.tar.xz 160208 BLAKE2B 01f4a8a77ac4c6d26c05eea9fda88461d8c688f0c80cbb3cc119260814c3766989b6eb9d7893729eca2239670b3a9d089000b5f1185b7650b0bdcf604c7195cf SHA512 44efb5dd29c83471acd64701320b2cb6057c6165c5b7602d2e0b7a40690a493c42ff3b28bc7924569d81c6e6a8ddc784b0df1c351919924807d61c9fdd2a4263

diff --git a/gui-libs/libpanel/libpanel-1.4.1.ebuild b/gui-libs/libpanel/libpanel-1.4.1.ebuild
new file mode 100644
index 000000000000..06f712398d95
--- /dev/null
+++ b/gui-libs/libpanel/libpanel-1.4.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="A dock/panel library for GTK 4"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libpanel"
+
+LICENSE="LGPL-3+"
+SLOT="1"
+KEYWORDS="~amd64 ~arm64"
+
+IUSE="examples gtk-doc +introspection +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.75:2
+	>=gui-libs/gtk-4.8:4[introspection?]
+	>=gui-libs/libadwaita-1.2:1
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use examples install-examples)
+		$(meson_feature introspection)
+		$(meson_feature gtk-doc docs)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use gtk-doc; then
+		mkdir "${ED}"/usr/share/gtk-doc || die
+		mv "${ED}"/usr/share/doc/panel-1.0 "${ED}"/usr/share/gtk-doc/ || die
+	fi
+}