[gentoo-commits] repo/gentoo:master commit in: dev-python/pyalsa/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c19c0e8b78b4c29f5475617bfd323a477aa8454e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  9 16:52:48 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Mar  9 16:54:03 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c19c0e8b

dev-python/pyalsa: PEP517, fix license

Closes: https://bugs.gentoo.org/909932
Closes: https://bugs.gentoo.org/921668
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild | 55 ++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild b/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild
new file mode 100644
index 000000000000..8c13d7107c02
--- /dev/null
+++ b/dev-python/pyalsa/pyalsa-1.2.7-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+# py3.12: seqtest*.py segfaults
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for ALSA library"
+HOMEPAGE="https://alsa-project.org/wiki/Main_Page"
+SRC_URI="https://www.alsa-project.org/files/pub/pyalsa/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+# Needs access to system's alsa configuration/devices
+RESTRICT="test"
+
+DEPEND="
+	media-libs/alsa-lib
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.1.6-no-build-symlinks.patch"
+)
+
+python_test() {
+	cd "${T}" || die
+
+	shopt -s nullglob
+	local test
+	local failed
+	for test in "${S}"/test/*.py ; do
+		${EPYTHON} "${test}" || {
+			eerror "${test} failed with ${EPYTHON}"
+			failed=1
+			break
+		}
+	done
+	shopt -u nullglob
+
+	if [[ ${failed} -eq 1 ]] ; then
+		die "${test} failed with ${EPYTHON}"
+	fi
+}