[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c3c4e687e00038dfc0c98caf4021d9472d695bc6
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Mar  6 18:26:21 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Mar  6 21:17:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c3c4e687

sys-kernel/gentoo-kernel: Bump to 6.1.81

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-kernel/gentoo-kernel/Manifest                  |   2 +
 .../gentoo-kernel/gentoo-kernel-6.1.81.ebuild      | 146 +++++++++++++++++++++
 2 files changed, 148 insertions(+)

diff --git a/sys-kernel/gentoo-kernel/Manifest b/sys-kernel/gentoo-kernel/Manifest
index 6965f2e0fa63..7b8dd04c5483 100644
--- a/sys-kernel/gentoo-kernel/Manifest
+++ b/sys-kernel/gentoo-kernel/Manifest
@@ -22,6 +22,8 @@ DIST genpatches-6.1-88.base.tar.xz 4653064 BLAKE2B 4f97e2991c632a38a16175613f6c2
 DIST genpatches-6.1-88.extras.tar.xz 3816 BLAKE2B 5d1aae241a64b9f1dfba85746b70dd1af5a96263f9385d5b264956239c2dd9237d6022819b61cc927177e10721c59e6b4c254e95ac9de771547f0a4c6e7e7960 SHA512 d083e6384786114c05ed5e4198ea90bd84b9959651f20f5c3f7786889583a607777845f4e377a8ad7a6684b91e97ee06cbb524e5827b46684872467eca6354b6
 DIST genpatches-6.1-89.base.tar.xz 4715392 BLAKE2B 36ac5c1d92985dba061e3ea8d1e9a661c877061ba27382843e3db15912513fd093bf6095152fffe5fb3e546c1d47b77ad2f70c15b4b3832ef4a62450ca96ed77 SHA512 53472cdf94ef6d65d7c8bfa58c7666a4a727684dba0dfde02c956368bbca3cddf3b51901ed66830354ad73a18432e8fc2f508b2326234e35d5975f7d77ae3e17
 DIST genpatches-6.1-89.extras.tar.xz 3812 BLAKE2B e5ea7db0e68120d8dcc8cb04b670a4cbe4b9f6ef169eb7815f2956c9b5c9f3570d418b3913801cdfa2779483bb6c5c97baf0500dba96025aa1f84e10b7208b1e SHA512 1d1b8860af0cdf6b31dfc596ea2d4662060f1c12f6661b9e3d5d127b0a001dcd2d4920d8b997f1bdbd47244d98a888986a6f3184054eaccf6bbb5bc3fcfacb3e
+DIST genpatches-6.1-90.base.tar.xz 4798868 BLAKE2B 3898a35ee9d3ea977c455a8432d512ed9f282f3b961b0046b79843bac59b136d9834c6fc128c5fdd2ba28b1d25e98c47b67bc3c50287cb05a372ed34d2b8982b SHA512 6bd2353dcb0caedfbd009f66d10e6201079c481101490fbe131168f0e46203446226c47a85059bcdeb8a3395ba79ed9ce0075c144ea8f94dffc0911958f679b4
+DIST genpatches-6.1-90.extras.tar.xz 3812 BLAKE2B 466c0b796df7406c228fd4dbad20f84c2fb99203ccae1a9e018a15a0314dafb478ef89dbeefaa012b0873a06fe3398b7f17f68bf8275283cafd0d258d44c3572 SHA512 1744cb7d90176d3eb09195679b51eb0aadfe5a3452dc2d2b299262eb7aeda3071bd0bbdadab2c05bd266c288eee5580e4da1190f308e8755140d454226f32204
 DIST genpatches-6.6-22.base.tar.xz 1119612 BLAKE2B e0e5cf468f1bfb7b76043b72528061a448a88ede3704fe5aab6fe9c5c5b4ff39362b8be25c5d10f1b0160c5071b4276e2c912606c857fd4ace2c8c92b54ea0ba SHA512 b71715d8bad12484035ab5d906db06fe570f40f0ff725beda500710837e9e90253b1fdbd2be40c0dc6d0226a8a1423e443b4bd7117142f346782401509f833be
 DIST genpatches-6.6-22.extras.tar.xz 3704 BLAKE2B c09db6ac1f713f404001c38c650731a0c8821c844eb7638b072cc0d135575df4f965cbd7c99c0261cc1021f97459266b20f153e428ba7a3b7973bb6453d0ceca SHA512 dfe66f78ca064ac0d6878da769dbdbc568db35bed24c8e2388bcc9a1ee63adef1e729ad9a3e737b5838c6f5473a7b9c6a6b44f97e95a900efbbf9562bf7462b6
 DIST genpatches-6.6-23.base.tar.xz 1164692 BLAKE2B d42ccd9e636a413ffdbdb7dac699169f38b80617234b83b6ce49418f7dfd568f6d6718ce97a42b4df2f3ee1efa81df1a02102c123b88603dc558f72dd18af7e7 SHA512 1671b5d07294f73fe547a0cce8df38b5da78dc1596aa136190bae38d9eddc8b896c34e778eb80971336caa851c7d6c7640a59186cf1ecff26b89b69bdc9fb0da

diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-6.1.81.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-6.1.81.ebuild
new file mode 100644
index 000000000000..1e3dc608d732
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-6.1.81.ebuild
@@ -0,0 +1,146 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-build toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 9 ))
+# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
+# forked to https://github.com/projg2/fedora-kernel-config-for-gentoo
+CONFIG_VER=6.1.7-gentoo
+GENTOO_CONFIG_VER=g11
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="
+	https://wiki.gentoo.org/wiki/Project:Distribution_Kernel
+	https://www.kernel.org/
+"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	https://github.com/projg2/gentoo-kernel-config/archive/${GENTOO_CONFIG_VER}.tar.gz
+		-> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
+	amd64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-x86_64-fedora.config
+			-> kernel-x86_64-fedora.config.${CONFIG_VER}
+	)
+	arm64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-aarch64-fedora.config
+			-> kernel-aarch64-fedora.config.${CONFIG_VER}
+	)
+	ppc64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-ppc64le-fedora.config
+			-> kernel-ppc64le-fedora.config.${CONFIG_VER}
+	)
+	x86? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-i686-fedora.config
+			-> kernel-i686-fedora.config.${CONFIG_VER}
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="debug hardened"
+REQUIRED_USE="
+	arm? ( savedconfig )
+	hppa? ( savedconfig )
+	riscv? ( savedconfig )
+	sparc? ( savedconfig )
+"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel-bin:${SLOT}
+"
+BDEPEND="
+	debug? ( dev-util/pahole )
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+
+QA_FLAGS_IGNORED="
+	usr/src/linux-.*/scripts/gcc-plugins/.*.so
+	usr/src/linux-.*/vmlinux
+	usr/src/linux-.*/arch/powerpc/kernel/vdso.*/vdso.*.so.dbg
+"
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	default
+
+	local biendian=false
+
+	# prepare the default config
+	case ${ARCH} in
+		amd64)
+			cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		arm)
+			return
+			;;
+		arm64)
+			cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		hppa)
+			return
+			;;
+		ppc)
+			# assume powermac/powerbook defconfig
+			# we still package.use.force savedconfig
+			cp "${WORKDIR}/${MY_P}/arch/powerpc/configs/pmac32_defconfig" .config || die
+			;;
+		ppc64)
+			cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		riscv)
+			return
+			;;
+		sparc)
+			return
+			;;
+		x86)
+			cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	local myversion="-gentoo-dist"
+	use hardened && myversion+="-hardened"
+	echo "CONFIG_LOCALVERSION=\"${myversion}\"" > "${T}"/version.config || die
+	local dist_conf_path="${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"
+
+	local merge_configs=(
+		"${T}"/version.config
+		"${dist_conf_path}"/base.config
+	)
+	use debug || merge_configs+=(
+		"${dist_conf_path}"/no-debug.config
+	)
+	if use hardened; then
+		merge_configs+=( "${dist_conf_path}"/hardened-base.config )
+
+		tc-is-gcc && merge_configs+=( "${dist_conf_path}"/hardened-gcc-plugins.config )
+
+		if [[ -f "${dist_conf_path}/hardened-${ARCH}.config" ]]; then
+			merge_configs+=( "${dist_conf_path}/hardened-${ARCH}.config" )
+		fi
+	fi
+
+	# this covers ppc64 and aarch64_be only for now
+	if [[ ${biendian} == true && $(tc-endian) == big ]]; then
+		merge_configs+=( "${dist_conf_path}/big-endian.config" )
+	fi
+
+	kernel-build_merge_configs "${merge_configs[@]}"
+}