[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-desktop/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     9fc1eb2efd13483a9df78d52442363d07007310e
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Mar  6 16:29:04 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Mar  6 19:31:31 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9fc1eb2e

kde-plasma/plasma-desktop: 5.27.11 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-desktop/Manifest                 |   1 +
 .../plasma-desktop/plasma-desktop-5.27.11.ebuild   | 180 +++++++++++++++++++++
 2 files changed, 181 insertions(+)

diff --git a/kde-plasma/plasma-desktop/Manifest b/kde-plasma/plasma-desktop/Manifest
index 671771b3f27e..61db42accd82 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -1,3 +1,4 @@
 DIST plasma-desktop-5.27.10.tar.xz 14724388 BLAKE2B 59a6bbe524a45b5331d46497fff9d83136906dc094dca571f43641cded5b8a9b9d117a1fcbccfe04c1877d52ee686a2c3949e5194fee611d798548c2d8bb501e SHA512 88d0aa3d4d57aa9286d1d45c1908c5a2fcc7005cc39105085c19cd22657b72b1ea4bfef5be59d3e68fe3851acb68d1b8ac8d4d33305e22c70877d66c266b03e9
+DIST plasma-desktop-5.27.11.tar.xz 14729900 BLAKE2B 3c023febf5c6dc72fdd3ca3696d5c5c84c5c099e8d66497e9fccde601a23ec19fc001d6b48f9b1160946ab46e0436e54dc20a91c56dafae455e8455fa558bfc4 SHA512 644bfe2235dcfc591ae66fc7090ca1e67fc8dfe80033c1b0bedc32cd76299a3f47e6c74eadee7ce80241efb31d20b561d9c06af457aa36b6528548b4eaee3eb9
 DIST plasma-desktop-6.0.1.tar.xz 15625032 BLAKE2B a67af368d3cf7ece3cea0a8fbd8b27c8993fe2e150cede749b60b9d09773745c382f4f3d4ef3236615595b6ee697cfa3ebdd5387b2bb3a544e7883b92b6a5e0f SHA512 7cc1d9430a3f66d7553e6dc3116e006c7fe81bb90c0a0224ac22cfa27cc1d124016d23eb2a4ad0e7a5e41db225e60ac1c9b2273ae620cb4422fdcf48c1d078b5
 DIST plasma-desktop-override-include-dirs-3.tar.xz 8288 BLAKE2B f05ece81d1b744d45a21a5963750011c1e815156bcaac6075fa67451ba8ab1ea0fcc5ca59c8109c6fe65f9d4db6ac003bb7e26bf011e124c5f9b7f9e1b3afef5 SHA512 fbfc08a4c057dab3ef96e3c56d5e6087916e952ff32280c6e23c0822e18739441082894ea36412be04eda0893a4e10b9a0fbf0a10e0e44f046b6e872840c4dbb

diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.27.11.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.27.11.ebuild
new file mode 100644
index 000000000000..39635d70171e
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.27.11.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-3"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="ibus kaccounts scim screencast +semantic-desktop"
+
+# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
+COMMON_DEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=kde-plasma/libplasma-${KFMIN}:5
+	>=kde-plasma/plasma-activities-${KFMIN}:5
+	>=kde-plasma/plasma-activities-stats-${KFMIN}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5[screencast?]
+	>=media-libs/phonon-4.11.0[qt5(+)]
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	ibus? (
+		app-i18n/ibus
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	kaccounts? (
+		kde-apps/kaccounts-integration:5
+		net-libs/accounts-qt[qt5(+)]
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/wayland-protocols-1.25
+	dev-libs/boost
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/kdeplasma-addons-5.25.50
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:*
+	>=kde-plasma/oxygen-${PVCUT}:5
+	media-fonts/noto-emoji
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	x11-misc/xdg-user-dirs
+	kaccounts? ( net-libs/signon-oauth2[qt5(+)] )
+	screencast? ( >=kde-plasma/kpipewire-${PVCUT}:5 )
+"
+BDEPEND="
+	dev-util/intltool
+	dev-util/wayland-scanner
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${WORKDIR}/${XORGHDRS}/${PN}-5.27.9-override-include-dirs.patch" # downstream patch
+)
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use ibus; then
+		sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+			-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if ! use scim; then
+		sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
+		-DEVDEV_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DSYNAPTICS_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		$(cmake_use_find_package ibus GLIB2)
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# test_kio_fonts needs D-Bus, bug #634166
+	# lookandfeel-kcmTest is unreliable for a long time, bug #607918
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "screen reader support" app-accessibility/orca
+	fi
+	ecm_pkg_postinst
+}