From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1606173-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (2048 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 365B2158041
	for <garchives@archives.gentoo.org>; Sat,  2 Mar 2024 11:40:03 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 7E7C0E29C2;
	Sat,  2 Mar 2024 11:40:02 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 5F19CE29C2
	for <gentoo-commits@lists.gentoo.org>; Sat,  2 Mar 2024 11:40:02 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 5E068340DE6
	for <gentoo-commits@lists.gentoo.org>; Sat,  2 Mar 2024 11:40:00 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id E599DE95
	for <gentoo-commits@lists.gentoo.org>; Sat,  2 Mar 2024 11:39:58 +0000 (UTC)
From: "Viorel Munteanu" <ceamac@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Viorel Munteanu" <ceamac@gentoo.org>
Message-ID: <1709379586.fba0e28ee763b38da3bd3140f309e04dc9014f46.ceamac@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-misc/fastfetch/Manifest app-misc/fastfetch/fastfetch-2.8.7.ebuild
X-VCS-Directories: app-misc/fastfetch/
X-VCS-Committer: ceamac
X-VCS-Committer-Name: Viorel Munteanu
X-VCS-Revision: fba0e28ee763b38da3bd3140f309e04dc9014f46
X-VCS-Branch: master
Date: Sat,  2 Mar 2024 11:39:58 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 3c9e0b89-95e4-49f3-ba42-3dce9a26c60d
X-Archives-Hash: cc8ae52032db1c8eeda4c088f0ee9ec6

commit:     fba0e28ee763b38da3bd3140f309e04dc9014f46
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  2 11:39:07 2024 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Sat Mar  2 11:39:46 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fba0e28e

app-misc/fastfetch: add 2.8.7

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest               |   1 +
 app-misc/fastfetch/fastfetch-2.8.7.ebuild | 115 ++++++++++++++++++++++++++++++
 2 files changed, 116 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index e234955b6321..0b0aa05ebe44 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
 DIST fastfetch-2.7.1.tar.gz 1000565 BLAKE2B 061d2175bdca879bb4ef1a2f29fd73b99a7325fb8de66f05eb1203008c34ef20ff122e57a785ee0a5abb0251004023958abb1d158bc49cd1b34f9e02f3d1c6bc SHA512 55d897af532141d429aa5b58ab1516347f14597bf249b70f0d5ab27d11e235911858143fc32356255bef201cb44cdd7698e8d49094fb7e61c2e425a6c8ac5fa1
 DIST fastfetch-2.8.6.tar.gz 1013523 BLAKE2B b55d70f51000fe10ed04caf7c5c88d52618420b11522233c447f8b71c8ea53f38d46ab0669a6969c07bfbbfd8c9f1442a453f612578c1ae345d50a7e702b7ffb SHA512 3695401d379c1bb120512b0245de48c91ac197306dc73253e96a8e196ef428253943c333492f85b5f142fdb34beda9b6c0ec6e148df0fff4a5042ef1845e3f98
+DIST fastfetch-2.8.7.tar.gz 1013771 BLAKE2B 119d2b44b050c374d924023cbaad25bf9e6ee5817edcc7ff4934985508e86c3125a820370947ea64c41b8307f8bb07a50960f762df39cdbc20e09a3d1dd90a8d SHA512 efc06434de0821d5fdb6f539f281e7d139c078181f9473522f7765ac936cf128d614268d8e46ed46d6ba1832872e1ada75a3a61cacb5aa503d9f3619fe6265ee

diff --git a/app-misc/fastfetch/fastfetch-2.8.7.ebuild b/app-misc/fastfetch/fastfetch-2.8.7.ebuild
new file mode 100644
index 000000000000..97a256518745
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.8.7.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.8.0:=
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}