[gentoo-commits] repo/gentoo:master commit in: dev-scheme/guile-zstd/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     0ec05555f73a7fa5a5e0f6cfa803c8ca407b48d8
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 28 19:33:50 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Wed Feb 28 19:47:35 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0ec05555

dev-scheme/guile-zstd: let pkg-config find zstd dir

See-also: https://github.com/trofi/nix-guix-gentoo/commit/6b79b1659191ffe625aebb5f85ac275e45b0b516
Closes: https://bugs.gentoo.org/877723
Bug: https://github.com/trofi/nix-guix-gentoo/issues/23
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild | 57 ------------------------
 dev-scheme/guile-zstd/guile-zstd-0.1.1-r2.ebuild | 55 +++++++++++++++++++++++
 2 files changed, 55 insertions(+), 57 deletions(-)

diff --git a/dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild b/dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild
deleted file mode 100644
index 7d00f87e4450..000000000000
--- a/dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="GNU Guile bindings to the zstd compression library"
-HOMEPAGE="https://notabug.org/guile-zstd/guile-zstd/"
-SRC_URI="https://notabug.org/${PN}/${PN}/archive/v${PV}.tar.gz
-	-> ${P}.tar.gz"
-S="${WORKDIR}"/${PN}
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-# In zstd-1.5.2-r2 library was moved from /usr/lib to /lib
-RDEPEND="
-	>=dev-scheme/guile-2.0.0:=
-	>=app-arch/zstd-1.5.2-r2
-"
-DEPEND="${RDEPEND}"
-
-DOCS=( AUTHORS ChangeLog NEWS README )
-
-# guile generates ELF files without use of C or machine code
-# It's a portage's false positive. bug #677600
-QA_PREBUILT='*[.]go'
-
-src_prepare() {
-	default
-
-	# Workaround gentoo-specific deviation where
-	# /usr/lib64/libzstd.so is a linker script that points to:
-	#   GROUP ( /lib64/libzstd.so.1 )
-	# This confuses guile-zstd and fails to open the library:
-	#   substitute: ice-9/boot-9.scm:1685:16: In procedure raise-exception:
-	#   substitute: In procedure load-foreign-library: file: "/usr/lib64/libzstd.so.1",
-	#     message: "file not found"
-	#   guix environment: error: `/usr/bin/guix substitute' died unexpectedly
-	sed "s|@ZSTD_LIBDIR@/libzstd.so.1|/$(get_libdir)/libzstd.so.1|" \
-		-i "${S}"/zstd/config.scm.in || die
-
-	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
-	find "${S}" -name "*.scm" -exec touch {} + || die
-
-	eautoreconf
-}
-
-src_install() {
-	default
-
-	# Workaround llvm-strip problem of mangling guile ELF debug
-	# sections: https://bugs.gentoo.org/905898
-	dostrip -x "/usr/$(get_libdir)/guile"
-}

diff --git a/dev-scheme/guile-zstd/guile-zstd-0.1.1-r2.ebuild b/dev-scheme/guile-zstd/guile-zstd-0.1.1-r2.ebuild
new file mode 100644
index 000000000000..553530bd3a34
--- /dev/null
+++ b/dev-scheme/guile-zstd/guile-zstd-0.1.1-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="GNU Guile bindings to the zstd compression library"
+HOMEPAGE="https://notabug.org/guile-zstd/guile-zstd/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://notabug.org/${PN}/${PN}.git"
+else
+	SRC_URI="https://notabug.org/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+# In zstd-1.5.5-r1 library was moved back from "/lib" to "/usr/lib".
+RDEPEND="
+	>=app-arch/zstd-1.5.5-r1
+	>=dev-scheme/guile-2.0.0:=
+"
+DEPEND="
+	${RDEPEND}
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_install() {
+	default
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}