[gentoo-commits] repo/proj/guru:dev commit in: dev-lang/hare/

["Haelwenn Monnier" <contact@hacktivis.me>]

commit:     c1f9c5d0bb84898d4374daffa660e2877d9f2a4c
Author:     Haelwenn (lanodan) Monnier <contact <AT> hacktivis <DOT> me>
AuthorDate: Sat Feb 24 07:28:22 2024 +0000
Commit:     Haelwenn Monnier <contact <AT> hacktivis <DOT> me>
CommitDate: Wed Feb 28 10:28:54 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=c1f9c5d0

dev-lang/hare: add 0.24.0

Signed-off-by: Haelwenn (lanodan) Monnier <contact <AT> hacktivis.me>

 dev-lang/hare/Manifest           |  1 +
 dev-lang/hare/hare-0.24.0.ebuild | 56 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-lang/hare/Manifest b/dev-lang/hare/Manifest
index ac820a8c45..60d52977cf 100644
--- a/dev-lang/hare/Manifest
+++ b/dev-lang/hare/Manifest
@@ -1,2 +1,3 @@
+DIST hare-0.24.0.tar.gz 767869 BLAKE2B 4e1e706a7e0623ebe71803dc591b362527dd140f025cb3529e95d9bec8bea464bc008d512e4981f1dcd34f770b8831a0d6dd37cb453ee54e01e900c1cd52c159 SHA512 d7b96bc031d432e0ca0a9186a043d4cd4af4d4b57be5ce4b913d6acd26cdb708d8c9ad8e2c64c78c192a11a96977d3e916985a548238591b3c4d177b9cc811d9
 DIST hare-009a8e873b688038aaf3c5e5e0b75c9205be56f5.tar.gz 728165 BLAKE2B ed3ecada9fc21e993548fa2b159b79ef3e8b537d3bd2ca54584127f315bf93e4440afa9cdf45f09aaac8665607a9e746b60ccd535a88aa538c6d7428b3d51e82 SHA512 16b8ef0a92c6ea8d6dabec283e4a7592fd301a11dd4bc837feff09f4f3743027efb615b2884eba2165ddfda197709324ed9fbb928d9d272f6585b3300c9d8582
 DIST hare-d94f355481a320fb2aec13ef62cb3bfe2416f5e4.tar.gz 716871 BLAKE2B 1805ca36c4e0faf581ad011d355eff63670e5dd13410e0aaaaee86c547ee7515a00577080c78e79c468274825e7905c386495e1b6520f60fd96d280f21e24044 SHA512 5638e213ac7dedd5a7a0c43bb481755e5cb5d9cbc227a0e08a53bbb4e9036e80111a5a7df2328bd4d1c0ede4cf703dd8a94f075a0850649b31770350223ecb96

diff --git a/dev-lang/hare/hare-0.24.0.ebuild b/dev-lang/hare/hare-0.24.0.ebuild
new file mode 100644
index 0000000000..70d3b17e6f
--- /dev/null
+++ b/dev-lang/hare/hare-0.24.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ "${PV}" = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/hare"
+	SLOT="0"
+else
+	MY_PV="$(ver_rs 3 -)"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://git.sr.ht/~sircmpwn/hare/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	SLOT="0/${PV}"
+	#KEYWORDS="~amd64 ~arm64 ~riscv"
+fi
+
+DESCRIPTION="The Hare systems programming language"
+HOMEPAGE="https://harelang.org/"
+LICENSE="MPL-2.0 GPL-3"
+
+# release policy: https://git.sr.ht/~sircmpwn/hare/tree/master/item/docs/release.md
+DEPEND="
+	~dev-lang/harec-0.24
+	>=sys-devel/qbe-1.2
+"
+BDEPEND="app-text/scdoc"
+RDEPEND="${DEPEND}"
+
+# hare and haredoc are built by hare
+QA_FLAGS_IGNORED="usr/bin/hare usr/bin/haredoc"
+
+src_configure() {
+	local target_arch
+	case ${ARCH} in
+		amd64 ) target_arch=x86_64 ;;
+		arm64 ) target_arch=aarch64 ;;
+		riscv ) target_arch=riscv64 ;;
+		* ) die "unsupported architecture: ${ARCH}" ;;
+	esac
+
+	# Note: PREFIX needs to be set early as it is used for HAREPATH
+	cp configs/linux.mk config.mk || die
+	sed -i \
+		-e "s;^ARCH =.*;ARCH = ${target_arch};" \
+		-e "s;^PREFIX =.*;PREFIX = ${EPREFIX}/usr;" \
+		-e 's;^AS =;AS ?=;' \
+		-e 's;^LD =;LD ?=;' \
+		-e 's;^AR =;AR ?=;' \
+		config.mk || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+}