[gentoo-commits] repo/gentoo:master commit in: x11-plugins/pidgin-led-notification/

["Andreas Schuerch" <nativemad@gentoo.org>]

commit:     c4ec4c1c97d2d32abe90ef7172743b20ed1ed1b9
Author:     Andreas Schuerch <nativemad <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 25 11:49:15 2024 +0000
Commit:     Andreas Schuerch <nativemad <AT> gentoo <DOT> org>
CommitDate: Sun Feb 25 11:50:41 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c4ec4c1c

x11-plugins/pidgin-led-notification: EAPI8 bump, fix LICENSE

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Andreas Schuerch <nativemad <AT> gentoo.org>

 .../pidgin-led-notification-0.1-r1.ebuild          | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/x11-plugins/pidgin-led-notification/pidgin-led-notification-0.1-r1.ebuild b/x11-plugins/pidgin-led-notification/pidgin-led-notification-0.1-r1.ebuild
new file mode 100644
index 000000000000..da59b6d4d098
--- /dev/null
+++ b/x11-plugins/pidgin-led-notification/pidgin-led-notification-0.1-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_PN="${PN/pidgin-/}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Pidgin plugin to notify by writing user defined strings to (led control) files"
+HOMEPAGE="https://sites.google.com/site/simohmattila/led-notification"
+SRC_URI="https://sites.google.com/site/simohmattila/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+
+RDEPEND="
+	net-im/pidgin[gtk]
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${P}-hardware.patch )
+
+src_compile() {
+	$(tc-getCC) \
+		${CFLAGS} -fPIC \
+		${CPPFLAGS} \
+		${LDFLAGS} \
+		$($(tc-getPKG_CONFIG) --cflags gtk+-2.0 pidgin) \
+		-shared ${MY_PN}.c -o ${MY_PN}.so \
+		$($(tc-getPKG_CONFIG) --libs gtk+-2.0 pidgin) || die
+}
+
+src_install() {
+	exeinto /usr/$(get_libdir)/pidgin
+	doexe ${MY_PN}.so
+
+	einstalldocs
+}