[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-utils/

["Michał Górny" <mgorny@gentoo.org>]

commit:     9d17186546e315da4f3117b62d8b00ac9690b1c2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 23 03:24:32 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Feb 23 03:37:14 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d171865

dev-python/oslo-utils: Bump to 7.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/oslo-utils/Manifest                |  1 +
 dev-python/oslo-utils/oslo-utils-7.1.0.ebuild | 57 +++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index fc5548949b1a..4ae4df00086c 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo.utils-7.0.0.tar.gz 103879 BLAKE2B d07af70592faac1821dc60f1ed0cd72fe948b1e105b515f18711b11152898fb2ab494d7eef2db965c43e961696b5f43eaca9d1c106f960d1ce91a9b5bb6ff924 SHA512 44202ec5de818b52b335026fdb24d1f771c24451422ad6b8328d4d14a4566b6c27b3cf04ba564d45686c9a4104ba1eec9a0874227498a707c5e9039b1d5c706c
+DIST oslo.utils-7.1.0.tar.gz 104775 BLAKE2B 6bdd137fd5ede65ea49faa872b8d93cec20ccc3b9564548384441e8e1b14526750a6d8e0263103a926bb52425c171a6e0d9dbcb0d373d1a9c8904774d03393b0 SHA512 7bd6e7e6cf097b239216d58ce8f9028eb0b2994115be15ac78d9b1bae4efb6f774fa72da4944ac79e9155d21a8e6dea3ac13b5445c8dd0f3452a6dd8143aabc4

diff --git a/dev-python/oslo-utils/oslo-utils-7.1.0.ebuild b/dev-python/oslo-utils/oslo-utils-7.1.0.ebuild
new file mode 100644
index 000000000000..3a01dee2b2fc
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-7.1.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.utils/
+	https://github.com/openstack/oslo.utils/
+	https://pypi.org/project/oslo.utils/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	<dev-python/netaddr-1[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	dev-python/tzdata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}"/install -name '*eventletutils*' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}