[gentoo-commits] repo/gentoo:master commit in: games-emulation/mgba/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     57e27ed33bd38cf241748422b4b26fad210c8b01
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 22 05:11:15 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Feb 22 06:14:30 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=57e27ed3

games-emulation/mgba: drop 0.10.2-r1

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-emulation/mgba/Manifest              |   1 -
 games-emulation/mgba/mgba-0.10.2-r1.ebuild | 109 -----------------------------
 2 files changed, 110 deletions(-)

diff --git a/games-emulation/mgba/Manifest b/games-emulation/mgba/Manifest
index ab81e1e91319..e8faf3bf19e9 100644
--- a/games-emulation/mgba/Manifest
+++ b/games-emulation/mgba/Manifest
@@ -1,2 +1 @@
-DIST mgba-0.10.2.tar.gz 14323388 BLAKE2B fb2e652b76871c9a9ffdbf049965ca4a62ee8fed48b547a4e7d514587535f172a7e3b21ec138b8660707a2fbdc19268985191d10eb268e7ed0f059c5a8c81216 SHA512 4063cde6dee9cc07025fa997e401ddd4b28240a9e53cee571ef8aec65cb6cf56b821f0020af1cf00d4f97353efbd4dc39ccd55bc6a3bdf0448ee34736bfd6499
 DIST mgba-0.10.3.tar.gz 14350721 BLAKE2B 2109c53455ece7beba0af30787cd75cad85db334be44e41b51f579f813393f8d83c5c9537832b190bb8b0ac1c28d78e92adb6af23191b17b463847df3360f656 SHA512 de92725a18f00ec8645a75cf434a667bfc5aba954d0ae8be188241371a4a310214123be2cec13d20dbff4f660b401364efb51c43c7bdc24eea40454949062a52

diff --git a/games-emulation/mgba/mgba-0.10.2-r1.ebuild b/games-emulation/mgba/mgba-0.10.2-r1.ebuild
deleted file mode 100644
index 0abe311a8e9c..000000000000
--- a/games-emulation/mgba/mgba-0.10.2-r1.ebuild
+++ /dev/null
@@ -1,109 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{3..4} )
-inherit cmake lua-single xdg
-
-if [[ ${PV} == 9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
-else
-	SRC_URI="https://github.com/mgba-emu/mgba/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 arm64 ppc64 x86"
-fi
-
-DESCRIPTION="Game Boy Advance Emulator"
-HOMEPAGE="https://mgba.io/"
-
-LICENSE="MPL-2.0 BSD LGPL-2.1+ public-domain discord? ( MIT )"
-SLOT="0/$(ver_cut 1-2)"
-IUSE="debug discord elf ffmpeg gles2 gles3 gui libretro lua +opengl +sdl +sqlite test"
-REQUIRED_USE="
-	gui? ( || ( gles2 gles3 opengl ) sqlite )
-	lua? ( ${LUA_REQUIRED_USE} )"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	media-libs/libpng:=
-	sys-libs/zlib:=[minizip]
-	debug? ( dev-libs/libedit )
-	elf? ( dev-libs/elfutils )
-	ffmpeg? ( media-video/ffmpeg:= )
-	gles2? ( media-libs/libglvnd )
-	gles3? ( media-libs/libglvnd )
-	lua? ( ${LUA_DEPS} )
-	opengl? ( media-libs/libglvnd )
-	gui? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtmultimedia:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtwidgets:5
-	)
-	sdl? ( media-libs/libsdl2[sound,joystick,gles2?,opengl?,video] )
-	sqlite? ( dev-db/sqlite:3 )"
-DEPEND="
-	${RDEPEND}
-	test? ( dev-util/cmocka )"
-BDEPEND="
-	gui? ( dev-qt/linguist-tools:5 )
-	lua? ( virtual/pkgconfig )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.10.0-optional-updater.patch
-)
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_CINEMA=$(usex test)
-		-DBUILD_GL=$(usex opengl)
-		-DBUILD_GLES2=$(usex gles2)
-		-DBUILD_GLES3=$(usex gles3)
-		-DBUILD_LIBRETRO=$(usex libretro)
-		-DBUILD_QT=$(usex gui)
-		-DBUILD_ROM_TEST=ON #918855
-		-DBUILD_SDL=$(usex sdl) # also used for gamepads in QT build
-		-DBUILD_SUITE=$(usex test)
-		-DBUILD_UPDATER=OFF
-		-DENABLE_SCRIPTING=$(usex lua)
-		-DMARKDOWN=OFF #752048
-		-DUSE_DEBUGGERS=$(usex debug)
-		-DUSE_DISCORD_RPC=$(usex discord)
-		-DUSE_EDITLINE=$(usex debug)
-		-DUSE_ELF=$(usex elf)
-		-DUSE_EPOXY=OFF
-		-DUSE_FFMPEG=$(usex ffmpeg)
-		-DUSE_GDB_STUB=$(usex debug)
-		-DUSE_LIBZIP=OFF
-		-DUSE_LZMA=ON
-		-DUSE_MINIZIP=ON
-		-DUSE_PNG=ON
-		-DUSE_SQLITE3=$(usex sqlite)
-		-DUSE_ZLIB=ON
-		$(usev libretro -DLIBRETRO_LIBDIR="${EPREFIX}"/usr/$(get_libdir)/libretro)
-	)
-	use lua && mycmakeargs+=( -DUSE_LUA=$(ver_cut 1-2 $(lua_get_version)) )
-
-	cmake_src_configure
-}
-
-src_test() {
-	# CMakeLists.txt forces SKIP_RPATH=ON when PREFIX=/usr
-	local -x LD_LIBRARY_PATH=${BUILD_DIR}:${LD_LIBRARY_PATH}
-
-	cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	use !test || rm "${ED}"/usr/bin/mgba-cinema || die
-
-	rm -r "${ED}"/usr/share/doc/${PF}/{LICENSE,licenses} || die
-}