[gentoo-commits] repo/gentoo:master commit in: app-admin/vault/

["Zac Medico" <zmedico@gentoo.org>]

commit:     55adaddc0bf44c99ba2cc592eced00ff4d34eef4
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 20 04:03:31 2024 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Tue Feb 20 04:06:09 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=55adaddc

app-admin/vault: add 1.14.9

Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-admin/vault/Manifest            |  2 +
 app-admin/vault/vault-1.14.9.ebuild | 86 +++++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/app-admin/vault/Manifest b/app-admin/vault/Manifest
index af6b94a1bdf1..ed9fdd0f316c 100644
--- a/app-admin/vault/Manifest
+++ b/app-admin/vault/Manifest
@@ -2,3 +2,5 @@ DIST vault-1.14.5-vendor.tar.gz 71839384 BLAKE2B 845416db5d69c400d5e9603bd42b2d7
 DIST vault-1.14.5-webui.tar.xz 1670796 BLAKE2B 8629de337f2c708553752409a1c8ddc94e421adb34c7b31116f4154e06eed6e7ffb0355cd7ff91d7ec42f1fb1a35737732d530a8587cf515a0636b0a5dbffb38 SHA512 32ff0d720282f0539288f3ee111b91d43b9098bd4ea309d11f638c9f0c4a0a9276fe2f940573d9d664dcea33945f08ac33488ad05d37b372042e859b6d2f7e97
 DIST vault-1.14.8-vendor.tar.gz 71869146 BLAKE2B 5875056d5ec53396ed53db7fd4891a6fbc3c5449a3f2409e11a409ed00cca2c0741e755a31c9d9c1b777c52a0b136cfc30be498a9321e9a0ff317b82e4c35d0e SHA512 e02c6fa1f09ccbb53420dc3919151a5783c4b861c8601ff5079db03a4be926d00a3a963130942f629dda8178275728ddfdcb537f1188e2279c67733883a0178c
 DIST vault-1.14.8-webui.tar.xz 1680312 BLAKE2B c698adc325633b1dc59dea3b09692da0476a5f3dbd1f69f1e68243fa903e4590b152846f2dabd4b7f5f492467fcdc52c0afd82bfe1a956b1b69f11da403fab9c SHA512 a25faa74614b31688bb91c4ac2b6a105426be632cc417e94ef14c60a388f076eaec006e07a9784047422b70ce9d9c9fd33e6fb8ef3595b7f1a6468739da8e1c6
+DIST vault-1.14.9-vendor.tar.gz 71845081 BLAKE2B ea25a6ba8ac293971170688b4ce3845ba19a5af746c3d96860420d74f8c0af33ea118a47d17117dbd520675739c44ed76118ef126c5b53e4c4adb0924cda58d5 SHA512 00ff45f986889d17ebe59c27aeaf8132270e5f06883bf84ce10721c9e2943a25ad8b86be3271991c824369ad5545258b3c01600f1dda06487751ff806b1d76b9
+DIST vault-1.14.9-webui.tar.xz 1677212 BLAKE2B db4da051a8c0a62e99c1f2070f3c022fc934350b255d21b360b3b3b53555942f1ac6c4ef15ed7d8a2519f05752406add63837317615afb387b0fc407f5ab8410 SHA512 2f54dd24fb9a4e2e774dd4212a605126a9d4e4975a97a01c88c94bce8e6f10174fe07235d402dd43ae31aacf4371f77272e4446d972d2e7304745186b0e6dbb7

diff --git a/app-admin/vault/vault-1.14.9.ebuild b/app-admin/vault/vault-1.14.9.ebuild
new file mode 100644
index 000000000000..1ca68af3ed4e
--- /dev/null
+++ b/app-admin/vault/vault-1.14.9.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit fcaps go-module systemd
+
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/"
+
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+SRC_URI="https://github.com/zmedico/vault/archive/refs/tags/v${PV}-vendor.tar.gz -> ${P}-vendor.tar.gz
+	webui? (
+		https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
+	)"
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+IUSE="+webui"
+
+BDEPEND="
+	app-arch/zip
+	dev-go/gox
+	>=dev-lang/go-1.21"
+COMMON_DEPEND="acct-group/vault
+	acct-user/vault"
+	DEPEND="${COMMON_DEPEND}"
+	RDEPEND="${COMMON_DEPEND}"
+
+FILECAPS=(
+	-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+RESTRICT="test"
+S=${WORKDIR}/${P}-vendor
+
+src_unpack() {
+	default
+}
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+		-e "s|^BUILD_DATE=.*|BUILD_DATE=$(date +%Y-%m-%dT%H:%M:%SZ)|" \
+		-i scripts/build.sh || die
+	sed -e "/hooks/d" \
+		-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
+		-e "s/gofumpt/gofmt/g" \
+		-i Makefile || die
+	if [[ -d "${WORKDIR}/http/web_ui" ]]; then
+		rm -rf "${S}/http/web_ui" || die
+		mv "${WORKDIR}/http/web_ui" "${S}/http/web_ui" ||
+			die "mv failed"
+	else
+		mkdir -p "${S}/http/web_ui" || die
+		touch "${S}/http/web_ui/no_web_ui" || die
+	fi
+}
+
+src_compile() {
+	mkdir "${T}"/bin || die
+	BUILD_TAGS="$(usex webui ui '')" \
+	GOPATH="${T}" \
+	XC_ARCH=$(go env GOARCH) \
+	XC_OS=$(go env GOOS) \
+	XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+	emake bin
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md
+	insinto /etc/${PN}.d
+	doins "${FILESDIR}/"*.json.example
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}