[gentoo-commits] repo/gentoo:master commit in: dev-lang/qore/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     1bb45e202cbda77e18250aa4bef9b5104223981f
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 19 14:56:08 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Feb 19 15:30:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1bb45e20

dev-lang/qore: bump to 1.19.2

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-lang/qore/Manifest           |  1 +
 dev-lang/qore/qore-1.19.2.ebuild | 76 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/dev-lang/qore/Manifest b/dev-lang/qore/Manifest
index 4183d9e8cd07..f0801e744773 100644
--- a/dev-lang/qore/Manifest
+++ b/dev-lang/qore/Manifest
@@ -1 +1,2 @@
 DIST qore-1.19.1.tar.gz 3933768 BLAKE2B 8e3002a55f1cf15f22ff604b1ceaf71995727510e365ae6ab03b71a91ddc1a82c5d6d89514b989a3509a5b39228fcf8fe11b6d88df8af784cace9b56b9d22482 SHA512 bf2203f8fe81cd4a604e06859380664f5cf635f5496e1ce6b6d5760d4cba82e510c78acef7ced4fdacd6df722f6eb305307106f12df3201003858a5a55256d9e
+DIST qore-1.19.2.tar.gz 3937953 BLAKE2B 136fd456dc6f262c3c1237448945c7d79b6c48a31c63e5213c7f03a695cda40d91605fc5f8f7887354ae47741342233228107ee327c192b449665fdec0664e62 SHA512 b79ecd1ed9ee934039e143711941a8317e02220403c934865632b37f030797520f0db434ef517e2d813f35a37d966f7c5a745202969fcee32494c4972f503fb1

diff --git a/dev-lang/qore/qore-1.19.2.ebuild b/dev-lang/qore/qore-1.19.2.ebuild
new file mode 100644
index 000000000000..85ee3b1fc485
--- /dev/null
+++ b/dev-lang/qore/qore-1.19.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Qore, the embeddable multithreaded scripting language"
+HOMEPAGE="http://qore.org/
+	https://github.com/qorelanguage/qore/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/qorelanguage/${PN}.git"
+else
+	SRC_URI="https://github.com/qorelanguage/${PN}/archive/release-${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-release-${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+	app-arch/bzip2:=
+	dev-libs/libpcre:=
+	dev-libs/mpfr:=
+	dev-libs/openssl:=
+	sys-libs/zlib:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	# Needs "bison" and "flex" exactly.
+	unset LEX
+	unset YACC
+
+	local -a myconf=(
+		--disable-optimization
+		--disable-profile
+		--disable-static-bz2
+		--disable-static-common
+		--disable-static-openssl
+		--disable-static-pcre
+		--disable-static-zlib
+		$(use_enable debug)
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	PATH="${S}:${PATH}" emake check
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name "*.la" -delete ||
+		die "failed to remove libtool files without corresponding static libraries"
+}