public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: kde-plasma/discover/
Date: Sat, 17 Feb 2024 20:14:29 +0000 (UTC)	[thread overview]
Message-ID: <1708200853.7d1604a105f47e16ecb39a0b74065dc32d6a00d6.asturm@gentoo> (raw)

commit:     7d1604a105f47e16ecb39a0b74065dc32d6a00d6
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 17 20:09:08 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Feb 17 20:14:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7d1604a1

kde-plasma/discover: Add missing dev-libs/appstream[qt5] USE-dep

Upstream commit 38012c10a4bc183ad2c5bd3e0ef2161f104b63d4

See also kde overlay commit 9bcd4e6008e13390693e08524783ac5b18561df4

Closes: https://bugs.gentoo.org/924821
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/discover/discover-5.27.10.1-r1.ebuild | 96 ++++++++++++++++++++++++
 1 file changed, 96 insertions(+)

diff --git a/kde-plasma/discover/discover-5.27.10.1-r1.ebuild b/kde-plasma/discover/discover-5.27.10.1-r1.ebuild
new file mode 100644
index 000000000000..005c6dbe56f7
--- /dev/null
+++ b/kde-plasma/discover/discover-5.27.10.1-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma resources management GUI"
+HOMEPAGE="https://userbase.kde.org/Discover"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+firmware flatpak snap telemetry webengine"
+
+# libmarkdown (app-text/discount) only used in PackageKitBackend
+DEPEND="
+	>=dev-libs/appstream-0.15.3:=[qt5(-)]
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/purpose-${KFMIN}:5
+	firmware? ( >=sys-apps/fwupd-1.5.0 )
+	flatpak? ( sys-apps/flatpak )
+	snap? ( sys-libs/snapd-glib:=[qt5] )
+	telemetry? ( kde-frameworks/kuserfeedback:5 )
+	webengine? ( >=dev-qt/qtwebview-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	snap? ( app-containers/snapd )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-5.25.90-tests-optional.patch" )
+
+src_prepare() {
+	ecm_src_prepare
+	# we don't need it with PackageKitBackend off
+	ecm_punt_kf_module Archive
+	# we don't do anything with this
+	sed -e "s/^pkg_check_modules.*RpmOstree/#&/" \
+		-e "s/^pkg_check_modules.*Ostree/#&/" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# TODO: Port PackageKit's portage back-end to python3
+		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
+		# Automated updates will not work for us
+		# https://invent.kde.org/plasma/discover/-/merge_requests/142
+		-DWITH_KCM=OFF
+		-DBUILD_DummyBackend=OFF
+		-DBUILD_FlatpakBackend=$(usex flatpak)
+		-DBUILD_FwupdBackend=$(usex firmware)
+		-DBUILD_RpmOstreeBackend=OFF
+		-DBUILD_SnapBackend=$(usex snap)
+		-DBUILD_SteamOSBackend=OFF
+		$(cmake_use_find_package telemetry KUserFeedback)
+		$(cmake_use_find_package webengine Qt5WebView)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 686392: needs network connection
+	local myctestargs=(
+		-E "(knsbackendtest|flatpaktest)"
+	)
+
+	ecm_src_test
+}


             reply	other threads:[~2024-02-17 20:14 UTC|newest]

Thread overview: 40+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-02-17 20:14 Andreas Sturmlechner [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-01-10  9:54 [gentoo-commits] repo/gentoo:master commit in: kde-plasma/discover/ WANG Xuerui
2024-09-21  8:29 Andreas Sturmlechner
2024-04-28 13:16 Andrew Ammerlaan
2024-04-26 10:38 Andrew Ammerlaan
2024-03-06 19:19 Arthur Zamarin
2024-03-05 17:22 Arthur Zamarin
2024-02-25  6:08 Andrew Ammerlaan
2024-02-17 20:14 Andreas Sturmlechner
2024-01-30 20:26 Andreas Sturmlechner
2024-01-16  8:40 Andreas Sturmlechner
2023-09-30 10:00 Andreas Sturmlechner
2023-05-10  7:51 Andreas Sturmlechner
2023-05-10  7:51 Andreas Sturmlechner
2022-11-16  8:55 WANG Xuerui
2022-10-06  9:07 Andreas Sturmlechner
2022-09-25 18:50 Andreas Sturmlechner
2022-08-07 15:51 Andreas Sturmlechner
2022-03-08 17:18 Andreas Sturmlechner
2021-11-30 14:33 Andreas Sturmlechner
2021-11-13 17:28 Andreas Sturmlechner
2021-06-10 18:05 Georgy Yakovlev
2021-05-07 22:14 Andreas Sturmlechner
2021-04-06 20:08 Andreas Sturmlechner
2021-04-06 19:51 Sam James
2021-04-06 19:47 Sam James
2021-04-04 16:03 Thomas Deutschmann
2020-11-18 21:09 Andreas Sturmlechner
2020-11-13  0:32 Thomas Deutschmann
2020-10-29 18:24 Georgy Yakovlev
2020-10-28 16:23 Sam James
2020-04-23 22:07 Andreas Sturmlechner
2019-05-21 20:32 Andreas Sturmlechner
2019-05-18 17:24 Andreas Sturmlechner
2019-03-10 22:46 Andreas Sturmlechner
2019-03-02 13:58 Andreas Sturmlechner
2019-03-02 13:58 Andreas Sturmlechner
2019-03-01 10:05 Andreas Sturmlechner
2019-02-28 14:32 Mikle Kolyada
2019-02-25 17:05 Andreas Sturmlechner

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1708200853.7d1604a105f47e16ecb39a0b74065dc32d6a00d6.asturm@gentoo \
    --to=asturm@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox