[gentoo-commits] repo/proj/guru:dev commit in: media-sound/tidal-hifi-bin/

["Kostadin Shishmanov" <kocelfc@tutanota.com>]

commit:     b5c9ae8104f9331cf0521903b4463eaf6fa6802b
Author:     Kostadin Shishmanov <kocelfc <AT> tutanota <DOT> com>
AuthorDate: Fri Feb 16 21:38:24 2024 +0000
Commit:     Kostadin Shishmanov <kocelfc <AT> tutanota <DOT> com>
CommitDate: Fri Feb 16 21:38:24 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=b5c9ae81

media-sound/tidal-hifi-bin: add 5.9.0

Signed-off-by: Kostadin Shishmanov <kocelfc <AT> tutanota.com>

 media-sound/tidal-hifi-bin/Manifest                |   1 +
 .../tidal-hifi-bin/tidal-hifi-bin-5.9.0.ebuild     | 100 +++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/media-sound/tidal-hifi-bin/Manifest b/media-sound/tidal-hifi-bin/Manifest
index 5258ed5fcd..36ea51fd78 100644
--- a/media-sound/tidal-hifi-bin/Manifest
+++ b/media-sound/tidal-hifi-bin/Manifest
@@ -1 +1,2 @@
 DIST tidal-hifi-bin-5.8.0.tar.gz 110335163 BLAKE2B c2115b28014fae7a07ecabb2bf8c0653b3b897e9ea964a76c658c2eec5a25d213933c6a02609029e47ed04f6f26b99e6be0208b0f08a3f34506aa18d04642293 SHA512 91832766324ea3a65670bed19d40d8eb2e06385545200413fadd760db4d13674334a6ad007c3e2c605baccedf36ff2e5744152b593fc38135e4b38b99cf414ca
+DIST tidal-hifi-bin-5.9.0.tar.gz 110340819 BLAKE2B 9ce266441aace64718c773b8dd96f925342b38fb1b4d5d1718aec786a2c6825d14a74a94c77487a3cf9b20513561457a52706be3cea0c33ec84e5b624ade9ccb SHA512 f9ef34b04fb448906142d1f8222f9ccf6abb03328fc560e927f5bcc2a1f19955f2117aeb6151876fbb9cb7cc8646c5d61c3604e85beb7fe51e0201d75b28eb20

diff --git a/media-sound/tidal-hifi-bin/tidal-hifi-bin-5.9.0.ebuild b/media-sound/tidal-hifi-bin/tidal-hifi-bin-5.9.0.ebuild
new file mode 100644
index 0000000000..92fe1d3483
--- /dev/null
+++ b/media-sound/tidal-hifi-bin/tidal-hifi-bin-5.9.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN/-bin/}"
+
+CHROMIUM_LANGS="
+	af am ar bg bn ca cs da de el en-GB en-US es es-419 et fa fi fil fr gu he hi
+	hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv
+	sw ta te th tr uk ur vi zh-CN zh-TW
+"
+
+inherit chromium-2 desktop linux-info unpacker xdg
+
+DESCRIPTION="Web version of Tidal running in electron with Hi-Fi support thanks to Widevine."
+HOMEPAGE="https://github.com/Mastermindzh/tidal-hifi"
+SRC_URI="https://github.com/Mastermindzh/tidal-hifi/releases/download/${PV}/tidal-hifi-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/libgcrypt
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/mesa[gbm(+)]
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/libdrm
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+"
+
+DESTDIR="/opt/${PN}"
+
+QA_PREBUILT="*"
+
+CONFIG_CHECK="~USER_NS"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	default
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_prepare() {
+	default
+	# cleanup languages
+	pushd "locales/" >/dev/null || die "location change for language cleanup failed"
+	chromium_remove_language_paks
+	popd >/dev/null || die "location reset for language cleanup failed"
+	rm -rf "${S}"/resources/app.asar.unpacked/node_modules/register-scheme/build/node_gyp_bins
+	rm -rf "${S}"/resources/app.asar.unpacked/node_modules/abstract-socket/build/node_gyp_bins
+}
+
+src_install() {
+	doicon -s 256 "${FILESDIR}/${MY_PN}.png"
+
+	make_desktop_entry "/usr/bin/tidal-hifi" "TIDAL Hi-Fi" ${PN} "Network;AudioVideo;Audio;Video"
+
+	exeinto "${DESTDIR}"
+
+	doexe "${MY_PN}" chrome-sandbox libEGL.so libffmpeg.so libGLESv2.so libvk_swiftshader.so
+
+	insinto "${DESTDIR}"
+	doins chrome_100_percent.pak chrome_200_percent.pak icudtl.dat resources.pak snapshot_blob.bin v8_context_snapshot.bin
+	insopts -m0755
+	doins -r locales resources
+
+	# Chrome-sandbox requires the setuid bit to be specifically set.
+	# see https://github.com/electron/electron/issues/17972
+	fowners root "${DESTDIR}/chrome-sandbox"
+	fperms 4711 "${DESTDIR}/chrome-sandbox"
+
+	[[ -x chrome_crashpad_handler ]] && doins chrome_crashpad_handler
+
+	dosym "${DESTDIR}/${MY_PN}" "/usr/bin/${MY_PN}"
+}