[gentoo-commits] repo/gentoo:master commit in: app-misc/elasticsearch/

["Matt Jolly" <kangie@gentoo.org>]

commit:     359e2a05d0096d54b1b960b7b504ea8792b868c2
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 14 15:39:31 2024 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Wed Feb 14 15:39:31 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=359e2a05

app-misc/elasticsearch: drop 8.11.1

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 app-misc/elasticsearch/Manifest                    |   1 -
 app-misc/elasticsearch/elasticsearch-8.11.1.ebuild | 102 ---------------------
 2 files changed, 103 deletions(-)

diff --git a/app-misc/elasticsearch/Manifest b/app-misc/elasticsearch/Manifest
index 565d40327084..0be068e93bd5 100644
--- a/app-misc/elasticsearch/Manifest
+++ b/app-misc/elasticsearch/Manifest
@@ -1,4 +1,3 @@
 DIST elasticsearch-7.17.16-no-jdk-linux-x86_64.tar.gz 168795535 BLAKE2B 642ae6f07db953e7fa783dcd63c6dcebab61e85ea600bede09e9596bf9dee2d71c43e5c28b80bd4c091d792ed3a95d10cc75ffb1074ad4b3cfceb081ed25027f SHA512 3755373f5068a08e4619b4e922bc2d3d97d41791dbf5aa84564574fc84abee9c567b16095cf0e11d48910627e3c183ff1193bf2d5ade59891bea2b3f994aa7df
-DIST elasticsearch-8.11.1-linux-x86_64.tar.gz 630398135 BLAKE2B 5118f995f3b53242898770ea2a0a8b2c3c23fa3a117453d505685903b7e00e44f081d7454f4198baa2e36f265e9c565cf3c41ffc04d2ffd214ac30dc6398ff5b SHA512 3d11f96a158e12d0a376867355f2ee1bd76b00a8b5e1aff97cac026631892544ccabeb8f2422e0347f8222b85784a98d1a893615547981f47403116baf2070ef
 DIST elasticsearch-8.11.3-linux-x86_64.tar.gz 630500349 BLAKE2B ab10c0db6a9df6352a33844c7dbee9f45bc93257904a5d0a0966352d4755f867fafad6858e7765ca88070806b553c46a7df5206078a66121a568921bdbe0d801 SHA512 63c724acbb756ebe8ad2c9d965a2828e1a5e08d215652ba8c876218a2beb1702c204e9199cf362514bcd3230bcb133e0449bb4da3473aac5008d35fa7a86c832
 DIST elasticsearch-8.12.1-linux-x86_64.tar.gz 621183584 BLAKE2B e168cf9549a22c2c8b049638f7039b5f43f6384da0a10627fbe0671a0a5a99f8a4e40f7c914d820d94dd42b2d328f3e20425eca3363478526d5faf07f9c5d782 SHA512 dcaea1ddb499724be40da936f6b7309e66458f0ac2852c63109cc8bd8fb6c88dbea0d8c9ce451c2fb0441a25fc137f5dc2894b7bea0242e0067bf29ffad48f54

diff --git a/app-misc/elasticsearch/elasticsearch-8.11.1.ebuild b/app-misc/elasticsearch/elasticsearch-8.11.1.ebuild
deleted file mode 100644
index bee839a3a00d..000000000000
--- a/app-misc/elasticsearch/elasticsearch-8.11.1.ebuild
+++ /dev/null
@@ -1,102 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit systemd tmpfiles
-
-DESCRIPTION="Free and Open, Distributed, RESTful Search Engine"
-HOMEPAGE="https://www.elastic.co/elasticsearch/"
-SRC_URI="https://artifacts.elastic.co/downloads/${PN}/${P}-linux-x86_64.tar.gz"
-
-LICENSE="Apache-2.0 BSD-2 Elastic-2.0 LGPL-3 MIT public-domain"
-SLOT="0/8"
-KEYWORDS="~amd64"
-
-DEPEND="acct-group/elasticsearch
-	acct-user/elasticsearch"
-RDEPEND="acct-group/elasticsearch
-	acct-user/elasticsearch
-	sys-libs/zlib
-	virtual/jre:17"
-
-QA_PREBUILT="usr/share/elasticsearch/modules/x-pack-ml/platform/linux-x86_64/\(bin\|lib\)/.*"
-QA_PRESTRIPPED="usr/share/elasticsearch/modules/x-pack-ml/platform/linux-x86_64/\(bin\|lib\)/.*"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-env.patch"
-)
-
-src_prepare() {
-	default
-
-	rm -rf jdk || die
-	sed -i -e "s:logs/:${EPREFIX}/var/log/${PN}/:g" config/jvm.options || die "Unable to set Elasticsearch log location"
-	# elasticsearch-env sets the envvar for the config location if not specified elsewhere;
-	# certain utilities try and source this. Although we patch ES_JAVA_HOME for Gentoo slightly earlier,
-	# it's easier to respect EPREFIX for the config location using sed.
-	sed -i "s:ES_PATH_CONF=\"\$ES_HOME\"/config:ES_PATH_CONF=\"${EPREFIX}/etc/${PN}\":" bin/elasticsearch-env  \
-		|| die "Unable to set Elasticsearch config directory"
-	rm LICENSE.txt NOTICE.txt || die
-	rmdir logs || die
-}
-
-src_install() {
-	keepdir /etc/${PN}
-	keepdir /etc/${PN}/scripts
-
-	insinto /etc/${PN}
-	doins -r config/.
-	rm -r config || die
-
-	fowners -R root:${PN} /etc/${PN}
-	fperms -R 2750 /etc/${PN}
-
-	insinto /usr/share/${PN}
-	doins -r .
-
-	keepdir /usr/share/${PN}/plugins
-
-	exeinto /usr/share/${PN}/bin
-	doexe "${FILESDIR}"/elasticsearch-systemd-pre-exec
-
-	fperms -R +x /usr/share/${PN}/bin
-	fperms -R +x /usr/share/${PN}/modules/x-pack-ml/platform/linux-x86_64/bin
-
-	keepdir /var/{lib,log}/${PN}
-	fowners ${PN}:${PN} /var/{lib,log}/${PN}
-	fperms 0750 /var/{lib,log}/${PN}
-
-	insinto /etc/sysctl.d
-	newins "${FILESDIR}/${PN}.sysctl.d" ${PN}.conf
-
-	newconfd "${FILESDIR}/${PN}.conf.4" ${PN}
-	newinitd "${FILESDIR}/${PN}.init.8" ${PN}
-
-	systemd_install_serviced "${FILESDIR}/${PN}.service.conf"
-	systemd_newunit "${FILESDIR}"/${PN}.service.4 ${PN}.service
-
-	newtmpfiles "${FILESDIR}"/${PN}.tmpfiles.d ${PN}.conf
-}
-
-pkg_postinst() {
-	# Elasticsearch will choke on our keep file and dodir will not preserve the empty dir
-	local KEEPFILE
-	KEEPFILE=$(find "${EROOT}/usr/share/${PN}/plugins/" -type f -name '.keep*')
-	rm "${KEEPFILE}" || die
-	tmpfiles_process /usr/lib/tmpfiles.d/${PN}.conf
-	if ! systemd_is_booted ; then
-		elog "You may create multiple instances of ${PN} by"
-		elog "symlinking the init script:"
-		elog "ln -sf /etc/init.d/${PN} /etc/init.d/${PN}.instance"
-		elog
-		elog "Please make sure you put elasticsearch.yml, log4j2.properties and scripts"
-		elog "from /etc/${PN} into the configuration directory of the instance:"
-		elog "/etc/${PN}/instance"
-		elog
-	fi
-	ewarn "Please make sure you have proper permissions on /etc/${PN}"
-	ewarn "prior to keystore generation or you may experience startup failures."
-	ewarn "chown root:${PN} /etc/${PN} && chmod 2750 /etc/${PN}"
-	ewarn "chown root:${PN} /etc/${PN}/${PN}.keystore && chmod 0660 /etc/${PN}/${PN}.keystore"
-}