[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     25dde033457d6f2849042147bb68865118fdf1ba
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  9 21:31:37 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Feb  9 22:25:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=25dde033

gnome-extra/evolution-data-server: add 3.50.4

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/evolution-data-server/Manifest         |   1 +
 .../evolution-data-server-3.50.4.ebuild            | 160 +++++++++++++++++++++
 2 files changed, 161 insertions(+)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 628c88ff6471..b053d4e15873 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1,3 +1,4 @@
 DIST evolution-data-server-3.48.4.tar.xz 4906356 BLAKE2B 13cbd21d8f6829d052227d3d328439d5f00a2cda2384ffeace791a563ed8acdcd707729ae032dbdbe16e530b2e6205c006412f1cbaa03e8fb6d669c2c75d67bd SHA512 35bc6653efdb70a110f39499945516408090f101319a3080c87f6e14f886e0f9283225c4c5b6a4c2af418b9928c5eb7fba2d319481c81af1fa87f7dd930f7215
 DIST evolution-data-server-3.50.2.tar.xz 4964152 BLAKE2B 7279a5bcb0399fdcce723336a052dca13efa6f0af6ef7371b7cb8e76fbd7e1b0313e7f677cea530de62a93770c35887fd70bac551338f9a89860e2529b1f1519 SHA512 9e2a34e06a446ae142535072a3d6916e31b7be987b114c111fb0687fa32a3fe4085ba5a09ccd77fb395d107e5c673130dc770bae74a50fdb566c91cd9de85610
 DIST evolution-data-server-3.50.3.tar.xz 4964556 BLAKE2B ddc37e2f1bfbcfbb1150a4fa89d5ffe1000c1f3e3b3f588f3f66d855986082c06034e87c2c4326bd4a8636eb22f078268883373235b816d55516fe83f999f623 SHA512 7c7142bd56846610a63b447a20dd6001bbebe146fed815230fa51ceb10d166975b1c9e49967ee87c90d5e70b598a76363885acadc6da0d314453a86546eb3064
+DIST evolution-data-server-3.50.4.tar.xz 4964564 BLAKE2B 7e3cf51856a1b12fcbd7e0b6ab98b8616c6e6047afb7fc59f8366920177c30b4d18f58cdd11825e81054ef46d61d3addf9eb646310510ba44f60bc5a2c2abe50 SHA512 e83f4222615d518e536a622808896b1da7e425e90d9b3c3545c6b850f955bd6d4b4a6815904fcdcfa373b3c01a6ce61377e259bc740941fc3f641e60eddacaed

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.50.4.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.50.4.ebuild
new file mode 100644
index 000000000000..b28a6b0606eb
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.50.4.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-data-server"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/64-11-21-4-2-27-2-27-4-0" # subslot = libcamel-1.2/libebackend-1.2/libebook-1.2/libebook-contacts-1.2/libecal-2.0/libedata-book-1.2/libedata-cal-2.0/libedataserver-1.2/libedataserverui-1.2/libedataserverui4-1.0 soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ldap kerberos oauth-gtk3 oauth-gtk4 vala +weather"
+REQUIRED_USE="
+	oauth-gtk3? ( gtk )
+	oauth-gtk4? ( gtk )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# glib-2.70 for build-time optional GPowerProfileMonitor
+RDEPEND="
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:3
+	>=dev-libs/glib-2.70:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4
+	>=dev-libs/nss-3.9
+	>=net-libs/libsoup-3.1.1:3.0
+	>=dev-libs/json-glib-1.0.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=x11-libs/gtk+-3.20:3
+		>=gui-libs/gtk-4.4:4
+		>=media-libs/libcanberra-0.25[gtk3]
+
+		oauth-gtk3? ( >=net-libs/webkit-gtk-2.34.0:4.1 )
+		oauth-gtk4? ( >=net-libs/webkit-gtk-2.39.90:6 )
+	)
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-4.2.0:4= )
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend)
+		>=net-libs/libsoup-3.1.1:3.0[vala]
+		dev-libs/libical[vala]
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.14
+		dev-util/gi-docgen
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="!test? ( test )"
+
+pkg_pretend() {
+	if has_version "gnome-extra/evolution-data-server[oauth(-)]" &&
+		! use oauth-gtk3 && ! use oauth-gtk4
+	then
+		ewarn "The previous installed version of gnome-extra/evolution-data-server"
+		ewarn "had USE=oauth enabled that is now split into USE=oauth-gtk3"
+		ewarn "and USE=oauth-gtk4.  Please consider enabling either (or both)"
+		ewarn "of these flags to preserve OAuth2 support."
+	fi
+}
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_setup
+	cmake_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+	eapply "${FILESDIR}"/3.50.2-c99.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+	  -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+	  -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+#		-DENABLE_GI_DOCGEN=$(usex gtk-doc)
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_GTK4=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2_WEBKITGTK=$(usex oauth-gtk3)
+		-DENABLE_OAUTH2_WEBKITGTK4=$(usex oauth-gtk4)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=ON
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}