[gentoo-commits] repo/gentoo:master commit in: dev-python/notebook/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     3f788699948827969b3093d0663eb012099ff0fa
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  9 18:04:33 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Feb  9 18:45:08 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3f788699

dev-python/notebook: add 7.0.8

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/notebook/Manifest              |  1 +
 dev-python/notebook/notebook-7.0.8.ebuild | 62 +++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-python/notebook/Manifest b/dev-python/notebook/Manifest
index ef57412f0c68..394169d19581 100644
--- a/dev-python/notebook/Manifest
+++ b/dev-python/notebook/Manifest
@@ -1 +1,2 @@
 DIST notebook-7.0.7.tar.gz 3936954 BLAKE2B 9171ae3974bd4eb36c804858224c386292a3772633017a8bf0c0ef408526278234b022087faad7930aa975c66762690e24a5a368bf9290937bdc8dff63757575 SHA512 05725f6bae2d916c9393f483a05696f6eb0e38a1b15a8427cbd61f508a06d78ead8a70c8764a00403c323b25a1278ea3a8daaf1ff5b5eeb0b35f6ed5e64ea638
+DIST notebook-7.0.8.tar.gz 3937092 BLAKE2B eb0276f42018e6c577a67ebbfc3c1bc7d81a9b1fd0ba039d1e6a7f3973edb35f3000a6720cf6af136a90c6268e711507155a872e02f91eeb39633e2faa55ae93 SHA512 d5616efcdf5863b5bb0b5d3be92654835773b49aa47660f2cd593240f9695ff2797233545be6215a5d0098501e8fa39f4123bf4348e1113b3be5ea29d51662f5

diff --git a/dev-python/notebook/notebook-7.0.8.ebuild b/dev-python/notebook/notebook-7.0.8.ebuild
new file mode 100644
index 000000000000..13cc93fa8932
--- /dev/null
+++ b/dev-python/notebook/notebook-7.0.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/notebook/
+	https://pypi.org/project/notebook/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-4.0.2[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-4.1[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	<dev-python/notebook-shim-0.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/nbval[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest-jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}