[gentoo-commits] repo/gentoo:master commit in: sci-libs/indilib/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     0f5df4cc0f3c8ca0386ddcb18d6245c7a583c9e8
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  5 20:33:19 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Feb  5 20:49:59 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f5df4cc

sci-libs/indilib: add 2.0.6

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-libs/indilib/Manifest             |  1 +
 sci-libs/indilib/indilib-2.0.6.ebuild | 80 +++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index d05290120206..38feedeea16f 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1,2 +1,3 @@
 DIST indilib-2.0.4.tar.gz 2778082 BLAKE2B 21573abeb054f6693d29e5e67908be8be06246c138dba7dd8815c80d338fe8dbc202b103454f8e9a0b97e0fa05d5464547f32a2aa6bc0fa6189ddabd1f67428c SHA512 cb8c05ed2d814350e8357dfb3fd42ce5f2db88a0d150b0feb63fcb85cadd70369bfce1600a60837e242e5815ad076923428c456f4b331ffe1a22a2c02e11ced4
 DIST indilib-2.0.5.tar.gz 2781981 BLAKE2B 7347c3e6cf5a32d1b136d8251253154fe7b25252070c34b8d03627e02c2cb3472ed2f44a12a7b7d87f95ba6b6b18a66a9cd528d5cba64c5df0a167fa6a20e017 SHA512 42cdc6d48ac1daf39ab96552dc134aa400bb847d2bcf22f0845aec9639ed44cdf9a2abb4b80d7c3b1c15b76b6f3d3a86333cc7a1a0b84033bc5404b78d758ea2
+DIST indilib-2.0.6.tar.gz 2793169 BLAKE2B ebbbc40074df8ea77b781d09d802506003e3f71ee9450730b145ff9d190d9a0d41bcb7db4449fb05f138d536b811d7fcbfd095516b2f73a163bd110335d3d14d SHA512 e00ca31f4bc2298529586e5c1cc35389e9dcc72f9b93a1c5a4594c4c3d11f72a63e02d228a582f4ee08b7986a8eed6ebe53cb19b25fa05ebe53243708d2a8ff5

diff --git a/sci-libs/indilib/indilib-2.0.6.ebuild b/sci-libs/indilib/indilib-2.0.6.ebuild
new file mode 100644
index 000000000000..afe230a6d6ed
--- /dev/null
+++ b/sci-libs/indilib/indilib-2.0.6.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/cpp-httplib:=
+	dev-cpp/nlohmann_json
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_SYSTEM_HTTPLIB=ON
+		-DINDI_SYSTEM_JSONLIB=ON
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_SHARED=ON
+		-DINDI_BUILD_STATIC=OFF
+		-DINDI_BUILD_XISF=OFF # not packaged
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}