[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtwayland/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     7c8340fe7c1e7892b49003e2a6266f4deeacfbfc
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  5 19:55:12 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Feb  5 20:07:10 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7c8340fe

dev-qt/qtwayland: Re-add IUSE=vulkan to 5.15.12

Closes: https://bugs.gentoo.org/923722
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-qt/qtwayland/qtwayland-5.15.12-r1.ebuild | 52 ++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-qt/qtwayland/qtwayland-5.15.12-r1.ebuild b/dev-qt/qtwayland/qtwayland-5.15.12-r1.ebuild
new file mode 100644
index 000000000000..c9d27b00e9e9
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-5.15.12-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+inherit qt5-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+SLOT=5/${QT5_PV} # bug 815646
+IUSE="compositor vulkan"
+
+RDEPEND="
+	dev-libs/wayland
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*:5=[egl,libinput,vulkan=]
+	media-libs/libglvnd
+	x11-libs/libxkbcommon
+	compositor? ( =dev-qt/qtdeclarative-${QT5_PV}*:5= )
+"
+DEPEND="${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="dev-util/wayland-scanner"
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		-no-feature-xcomposite-egl
+		-no-feature-xcomposite-glx
+		$(qt_use compositor feature-wayland-server)
+		$(qt_use compositor feature-wayland-dmabuf-server-buffer)
+		$(qt_use compositor feature-wayland-drm-egl-server-buffer)
+		$(qt_use compositor feature-wayland-shm-emulation-server-buffer)
+	)
+
+	use compositor && myqmakeargs+=(
+		$(qt_use vulkan feature-wayland-vulkan-server-buffer)
+	)
+
+	qt5-build_src_configure
+}
+
+src_install() {
+	qt5-build_src_install
+	rm "${D}${QT5_BINDIR}"/qtwaylandscanner || die
+}